#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.69)
AC_INIT([GNUnet-Guile], [0.0.1], [bug-gnunet@gnu.org], [gnunet-guile],
  [https://gnunet.org])
AC_CONFIG_AUX_DIR([build-aux])

AM_INIT_AUTOMAKE([1.12 foreign silent-rules subdir-objects \
 color-tests parallel-tests -Woverride -Wno-portability])

# Enable silent rules by default.
AM_SILENT_RULES([yes])

AC_CONFIG_SRCDIR([gnunet])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_HOST

dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
dnl Make sure they are available.
m4_pattern_forbid([PKG_CHECK_MODULES])
m4_pattern_forbid([GUILE_MODULE_AVAILABLE])

PKG_CHECK_MODULES([GUILE], [guile-2.2 >= 2.2.3])
AC_PATH_PROG([GUILE], [guile])
AC_PATH_PROG([GUILD], [guild])
if test "x$GUILD" = "x"; then
   AC_MSG_ERROR(['guild' binary not found; please check your Guile 2.x installation.])
fi

guilemoduledir="${datarootdir}/guile/site/2.2"
guileobjectdir="${libdir}/guile/site/2.2/site-ccache"
AC_SUBST([guilemoduledir])
AC_SUBST([guileobjectdir])

AC_CACHE_SAVE

PKG_CHECK_MODULES([GNUNETUTIL], [gnunetutil])
PKG_CHECK_MODULES([GNUNETFS], [gnunetfs])
PKG_CHECK_MODULES([GNUNETIDENTITY], [gnunetidentity])

GNUNETUTIL_LIBDIR="`$PKG_CONFIG --variable=libdir gnunetutil`"
GNUNETFS_LIBDIR="`$PKG_CONFIG --variable=libdir gnunetfs`"
GNUNETIDENTITY_LIBDIR="`$PKG_CONFIG --variable=libdir gnunetidentity`"

AC_SUBST([GNUNETUTIL_LIBDIR])
AC_SUBST([GNUNETFS_LIBDIR])
AC_SUBST([GNUNETIDENTITY_LIBDIR])

AC_CONFIG_FILES([
Makefile
gnunet/config.scm
doc/Makefile
])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])

AC_OUTPUT