Merge branch 'master' of ssh://git.gnunet.org/gnunet

5 files changed, 101 insertions, 8 deletions

diff --git a/contrib/Makefile.am b/contrib/Makefile.am
index f42fb684d..150e47ff0 100644
--- a/contrib/Makefile.am
+++ b/contrib/Makefile.am
@@ -53,6 +53,7 @@ EXTRA_DIST = \
  conf/gnunet/gnunet-user.conf \
  conf/nss/nssswitch.conf \
  conf/wireshark/wireshark.lua \
+ gnunet.m4 \
  $(PACKAGES_FILES) \
  $(INITD_FILES) \
  Makefile.inc \
@@ -77,3 +78,6 @@ test_gnunet_prefix_LDADD = \
   $(LTLIBICONV) \
   $(GN_LIBINTL) \
   $(LIBLTDL) -lunistring $(XLIB)
+
+aclocaldir = $(datadir)/aclocal
+aclocal_DATA = gnunet.m4
diff --git a/contrib/gnunet.m4 b/contrib/gnunet.m4
new file mode 100644
index 000000000..6d9332db3
--- /dev/null
+++ b/contrib/gnunet.m4
@@ -0,0 +1,72 @@
+# Autoconf macro for working with GNUnet
+# This file is in the public domain.
+#
+# AM_PATH_GNUNET([MINIMUM-VERSION = 0.15.3, [ACTION-IF-FOUND, [ACTION-IF-NOT-FOUND]]])
+# Find the GNUnet installation, either automatically or through the
+# --with-gnunet-prefix flag
+#
+# This macro runs the pkg-config and, if needed, the gnunet-config tool
+# provided by GNUnet itself.
+#
+# The gnunet-config tool can be overridden by setting the GNUNET_CONFIG
+# variable before executing the configure script.
+#
+# The variables GNUNET_CFLAGS and GNUNET_LIBS will be set to appropriate
+# values and are made available to Automake.
+AC_DEFUN([AM_PATH_GNUNET],
+[AC_ARG_WITH([gnunet-prefix],
+             [AS_HELP_STRING([--with-gnunet-prefix=PATH],
+                             [PATH to the GNUnet installation])],
+             [gnunet_prefix="$withval"],
+             [gnunet_prefix=""])
+ AC_ARG_ENABLE([debug-log],
+               [AS_HELP_STRING([--disable-debug-log],
+                               [Disable all DEBUG-level logging])],
+               [],
+               [enable_debug_log=yes])
+ AC_ARG_VAR([GNUNET_CONFIG],[The gnunet-config tool])
+ min_gnunet_version=m4_if([$1], ,0.15.3,$1)
+ # Make sure the specified version is at least the version with
+ # the features required to use this macro
+ AS_VERSION_COMPARE([$min_gnunet_version],[0.15.3],
+                    [AC_MSG_WARN([The specified GNUnet version $min_gnunet_version is too old.])
+                     AC_MSG_WARN([The minimum version has been set to 0.15.3])
+                     min_gnunet_version="0.15.3"])
+ AS_IF([test "x${GNUNET_CONFIG+set}" != "xset"],
+       [PKG_CHECK_MODULES([GNUNET],[gnunetutil >= $min_gnunet_version],
+                          [gnunet_pkgconfig=yes],[gnunet_pkgconfig=no])
+        AS_IF([test "x$gnunet_pkgconfig" = "xno" && test "x$gnunet_prefix" != "x"],
+              [gnunet_PATH="$PATH"
+               AS_IF([test "x$prefix" != "xNONE"],
+                     [gnunet_PATH="$prefix/bin${PATH_SEPARATOR}$prefix/usr/bin"])
+               AC_PATH_PROG([GNUNET_CONFIG],[gnunet-config],[no],[$gnunet_PATH])
+               AS_UNSET([gnunet_PATH])],
+              [GNUNET_CONFIG="pkg-config gnunetutil"])])
+ AC_MSG_CHECKING([if GNUnet version is >= $min_gnunet_version])
+ gnunet_result=no
+ AS_IF([test "x$GNUNET_CONFIG" != "xno" && test -n "$GNUNET_CONFIG"],
+       [gnunet_version=`$GNUNET_CONFIG --version | tr ' ' '\n' | sed -n '2p'`
+        AS_VERSION_COMPARE([$gnunet_version],[$min_gnunet_version],
+                           [gnunet_result=no],
+                           [gnunet_result=yes],
+                           [gnunet_result=yes])
+        AS_UNSET([gnunet_version])])
+ AS_IF([test "x$gnunet_result" != "xyes"],
+       [AC_MSG_RESULT([no])
+        m4_if([$3], ,:,[$3])],
+       [AC_MSG_RESULT([yes])
+        m4_if([$2], ,:,[$2])
+        AC_CHECK_HEADERS([sys/socket.h netinet/in.h byteswap.h])
+        AS_IF([test "x${GNUNET_CFLAGS+set}" != "xset"],
+              [GNUNET_CFLAGS=`$GNUNET_CONFIG --cflags`
+              AC_SUBST([GNUNET_CFLAGS])])
+        AS_IF([test "x${GNUNET_LIBS+set}" != "xset"],
+              [GNUNET_LIBS=`$GNUNET_CONFIG --libs`
+               AC_SUBST([GNUNET_LIBS])])
+        AS_IF([test "x$enable_debug_log" = "xno"],
+              [AC_DEFINE([GNUNET_EXTRA_LOGGING],
+                         [0],
+                         [0 if debug messages should be culled])])])
+ AS_UNSET([gnunet_result])
+ AS_UNSET([min_gnunet_version])
+])
diff --git a/contrib/services/systemd/tmpfiles-gnunet.conf b/contrib/services/systemd/tmpfiles-gnunet.conf
index ffffa3284..251b475c9 100644
--- a/contrib/services/systemd/tmpfiles-gnunet.conf
+++ b/contrib/services/systemd/tmpfiles-gnunet.conf
@@ -1,10 +1,10 @@
 # Typically placed into /usr/lib/tmpfiles.d/gnunet.conf
 d /var/lib/gnunet 0700 gnunet gnunet - -
-z /usr/lib/gnunet/gnunet-helper-dns 4750 root gnunetdns - -
-z /usr/lib/gnunet/gnunet-service-dns 2750 gnunet gnunetdns - -
-z /usr/lib/gnunet/libexec/gnunet-helper-vpn 4750 root root - -
-z /usr/lib/gnunet/libexec/gnunet-helper-transport-wlan 4750 root root - -
-z /usr/lib/gnunet/libexec/gnunet-helper-transport-bluetooth 4750 root root - -
-z /usr/lib/gnunet/libexec/gnunet-helper-exit 4750 root root - -
-z /usr/lib/gnunet/libexec/gnunet-helper-nat-server 4750 root root - -
-z /usr/lib/gnunet/libexec/gnunet-helper-nat-client 4750 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-dns 4750 root gnunetdns - -
+z /usr/lib/gnunet/libexec/gnunet-service-dns 2750 gnunet gnunetdns - -
+z /usr/lib/gnunet/libexec/gnunet-helper-vpn 4755 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-transport-wlan 4755 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-transport-bluetooth 4755 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-exit 4755 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-nat-server 4755 root root - -
+z /usr/lib/gnunet/libexec/gnunet-helper-nat-client 4755 root root - -
diff --git a/contrib/xdg-scheme-handler/README.md b/contrib/xdg-scheme-handler/README.md
new file mode 100644
index 000000000..919ae37f8
--- /dev/null
+++ b/contrib/xdg-scheme-handler/README.md
@@ -0,0 +1,8 @@
+XDG Scheme Handler for GNUnet URIs
+==================================
+
+To register the `gnunet://` URI scheme, launch the following commands from this
+directory as a privileged user:
+
+    install -Dm644 gnunet-uri.desktop /usr/share/applications/gnunet-uri.desktop
+    update-mime-database /usr/share/applications/
diff --git a/contrib/xdg-scheme-handler/gnunet-uri.desktop b/contrib/xdg-scheme-handler/gnunet-uri.desktop
new file mode 100644
index 000000000..4f847d20f
--- /dev/null
+++ b/contrib/xdg-scheme-handler/gnunet-uri.desktop
@@ -0,0 +1,9 @@
+[Desktop Entry]
+Name=GNUnet URI
+Exec=gnunet-uri %u
+GenericName=URI handler for the GNUnet network
+Icon=gnunet
+Type=Application
+Terminal=false
+NoDisplay=true
+MimeType=x-scheme-handler/gnunet;