cp

1 files changed, 35 insertions, 0 deletions

diff --git a/m4/ac_define_dir.m4 b/m4/ac_define_dir.m4
new file mode 100644
index 000000000..f7e028fca
--- /dev/null
+++ b/m4/ac_define_dir.m4
@@ -0,0 +1,35 @@
+dnl @synopsis AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])

+dnl

+dnl This macro _AC_DEFINEs VARNAME to the expansion of the DIR

+dnl variable, taking care of fixing up ${prefix} and such.

+dnl

+dnl VARNAME is offered as both a C preprocessor symbol, and an output

+dnl variable.

+dnl

+dnl Note that the 3 argument form is only supported with autoconf 2.13

+dnl and later (i.e. only where _AC_DEFINE supports 3 arguments).

+dnl

+dnl Examples:

+dnl

+dnl    AC_DEFINE_DIR(DATADIR, datadir)

+dnl    AC_DEFINE_DIR(PROG_PATH, bindir, [Location of installed binaries])

+dnl

+dnl @category Misc

+dnl @author Stepan Kasal <kasal@ucw.cz>

+dnl @author Andreas Schwab <schwab@suse.de>

+dnl @author Guido Draheim <guidod@gmx.de>

+dnl @author Alexandre Oliva

+dnl @version 2005-01-17

+dnl @license AllPermissive

+

+AC_DEFUN([AC_DEFINE_DIR], [

+  prefix_NONE=

+  exec_prefix_NONE=

+  test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix

+  test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix

+  eval ac_define_dir="\"[$]$2\""

+  AC_SUBST($1, "$ac_define_dir")

+  AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])

+  test "$prefix_NONE" && prefix=NONE

+  test "$exec_prefix_NONE" && exec_prefix=NONE

+])