aboutsummaryrefslogtreecommitdiff
path: root/m4/include_next.m4
diff options
context:
space:
mode:
Diffstat (limited to 'm4/include_next.m4')
-rw-r--r--m4/include_next.m4244
1 files changed, 244 insertions, 0 deletions
diff --git a/m4/include_next.m4 b/m4/include_next.m4
new file mode 100644
index 000000000..b3c784918
--- /dev/null
+++ b/m4/include_next.m4
@@ -0,0 +1,244 @@
1# include_next.m4 serial 18
2dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
3dnl This file is free software; the Free Software Foundation
4dnl gives unlimited permission to copy and/or distribute it,
5dnl with or without modifications, as long as this notice is preserved.
6
7dnl From Paul Eggert and Derek Price.
8
9dnl Sets INCLUDE_NEXT and PRAGMA_SYSTEM_HEADER.
10dnl
11dnl INCLUDE_NEXT expands to 'include_next' if the compiler supports it, or to
12dnl 'include' otherwise.
13dnl
14dnl INCLUDE_NEXT_AS_FIRST_DIRECTIVE expands to 'include_next' if the compiler
15dnl supports it in the special case that it is the first include directive in
16dnl the given file, or to 'include' otherwise.
17dnl
18dnl PRAGMA_SYSTEM_HEADER can be used in files that contain #include_next,
19dnl so as to avoid GCC warnings when the gcc option -pedantic is used.
20dnl '#pragma GCC system_header' has the same effect as if the file was found
21dnl through the include search path specified with '-isystem' options (as
22dnl opposed to the search path specified with '-I' options). Namely, gcc
23dnl does not warn about some things, and on some systems (Solaris and Interix)
24dnl __STDC__ evaluates to 0 instead of to 1. The latter is an undesired side
25dnl effect; we are therefore careful to use 'defined __STDC__' or '1' instead
26dnl of plain '__STDC__'.
27dnl
28dnl PRAGMA_COLUMNS can be used in files that override system header files, so
29dnl as to avoid compilation errors on HP NonStop systems when the gnulib file
30dnl is included by a system header file that does a "#pragma COLUMNS 80" (which
31dnl has the effect of truncating the lines of that file and all files that it
32dnl includes to 80 columns) and the gnulib file has lines longer than 80
33dnl columns.
34
35AC_DEFUN([gl_INCLUDE_NEXT],
36[
37 AC_LANG_PREPROC_REQUIRE()
38 AC_CACHE_CHECK([whether the preprocessor supports include_next],
39 [gl_cv_have_include_next],
40 [rm -rf conftestd1a conftestd1b conftestd2
41 mkdir conftestd1a conftestd1b conftestd2
42 dnl IBM C 9.0, 10.1 (original versions, prior to the 2009-01 updates) on
43 dnl AIX 6.1 support include_next when used as first preprocessor directive
44 dnl in a file, but not when preceded by another include directive. Check
45 dnl for this bug by including <stdio.h>.
46 dnl Additionally, with this same compiler, include_next is a no-op when
47 dnl used in a header file that was included by specifying its absolute
48 dnl file name. Despite these two bugs, include_next is used in the
49 dnl compiler's <math.h>. By virtue of the second bug, we need to use
50 dnl include_next as well in this case.
51 cat <<EOF > conftestd1a/conftest.h
52#define DEFINED_IN_CONFTESTD1
53#include_next <conftest.h>
54#ifdef DEFINED_IN_CONFTESTD2
55int foo;
56#else
57#error "include_next doesn't work"
58#endif
59EOF
60 cat <<EOF > conftestd1b/conftest.h
61#define DEFINED_IN_CONFTESTD1
62#include <stdio.h>
63#include_next <conftest.h>
64#ifdef DEFINED_IN_CONFTESTD2
65int foo;
66#else
67#error "include_next doesn't work"
68#endif
69EOF
70 cat <<EOF > conftestd2/conftest.h
71#ifndef DEFINED_IN_CONFTESTD1
72#error "include_next test doesn't work"
73#endif
74#define DEFINED_IN_CONFTESTD2
75EOF
76 gl_save_CPPFLAGS="$CPPFLAGS"
77 CPPFLAGS="$gl_save_CPPFLAGS -Iconftestd1b -Iconftestd2"
78dnl We intentionally avoid using AC_LANG_SOURCE here.
79 AC_COMPILE_IFELSE([AC_LANG_DEFINES_PROVIDED[#include <conftest.h>]],
80 [gl_cv_have_include_next=yes],
81 [CPPFLAGS="$gl_save_CPPFLAGS -Iconftestd1a -Iconftestd2"
82 AC_COMPILE_IFELSE([AC_LANG_DEFINES_PROVIDED[#include <conftest.h>]],
83 [gl_cv_have_include_next=buggy],
84 [gl_cv_have_include_next=no])
85 ])
86 CPPFLAGS="$gl_save_CPPFLAGS"
87 rm -rf conftestd1a conftestd1b conftestd2
88 ])
89 PRAGMA_SYSTEM_HEADER=
90 if test $gl_cv_have_include_next = yes; then
91 INCLUDE_NEXT=include_next
92 INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include_next
93 if test -n "$GCC"; then
94 PRAGMA_SYSTEM_HEADER='#pragma GCC system_header'
95 fi
96 else
97 if test $gl_cv_have_include_next = buggy; then
98 INCLUDE_NEXT=include
99 INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include_next
100 else
101 INCLUDE_NEXT=include
102 INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include
103 fi
104 fi
105 AC_SUBST([INCLUDE_NEXT])
106 AC_SUBST([INCLUDE_NEXT_AS_FIRST_DIRECTIVE])
107 AC_SUBST([PRAGMA_SYSTEM_HEADER])
108 AC_CACHE_CHECK([whether system header files limit the line length],
109 [gl_cv_pragma_columns],
110 [dnl HP NonStop systems, which define __TANDEM, have this misfeature.
111 AC_EGREP_CPP([choke me],
112 [
113#ifdef __TANDEM
114choke me
115#endif
116 ],
117 [gl_cv_pragma_columns=yes],
118 [gl_cv_pragma_columns=no])
119 ])
120 if test $gl_cv_pragma_columns = yes; then
121 PRAGMA_COLUMNS="#pragma COLUMNS 10000"
122 else
123 PRAGMA_COLUMNS=
124 fi
125 AC_SUBST([PRAGMA_COLUMNS])
126])
127
128# gl_CHECK_NEXT_HEADERS(HEADER1 HEADER2 ...)
129# ------------------------------------------
130# For each arg foo.h, if #include_next works, define NEXT_FOO_H to be
131# '<foo.h>'; otherwise define it to be
132# '"///usr/include/foo.h"', or whatever other absolute file name is suitable.
133# Also, if #include_next works as first preprocessing directive in a file,
134# define NEXT_AS_FIRST_DIRECTIVE_FOO_H to be '<foo.h>'; otherwise define it to
135# be
136# '"///usr/include/foo.h"', or whatever other absolute file name is suitable.
137# That way, a header file with the following line:
138# #@INCLUDE_NEXT@ @NEXT_FOO_H@
139# or
140# #@INCLUDE_NEXT_AS_FIRST_DIRECTIVE@ @NEXT_AS_FIRST_DIRECTIVE_FOO_H@
141# behaves (after sed substitution) as if it contained
142# #include_next <foo.h>
143# even if the compiler does not support include_next.
144# The three "///" are to pacify Sun C 5.8, which otherwise would say
145# "warning: #include of /usr/include/... may be non-portable".
146# Use `""', not `<>', so that the /// cannot be confused with a C99 comment.
147# Note: This macro assumes that the header file is not empty after
148# preprocessing, i.e. it does not only define preprocessor macros but also
149# provides some type/enum definitions or function/variable declarations.
150#
151# This macro also checks whether each header exists, by invoking
152# AC_CHECK_HEADERS_ONCE or AC_CHECK_HEADERS on each argument.
153AC_DEFUN([gl_CHECK_NEXT_HEADERS],
154[
155 gl_NEXT_HEADERS_INTERNAL([$1], [check])
156])
157
158# gl_NEXT_HEADERS(HEADER1 HEADER2 ...)
159# ------------------------------------
160# Like gl_CHECK_NEXT_HEADERS, except do not check whether the headers exist.
161# This is suitable for headers like <stddef.h> that are standardized by C89
162# and therefore can be assumed to exist.
163AC_DEFUN([gl_NEXT_HEADERS],
164[
165 gl_NEXT_HEADERS_INTERNAL([$1], [assume])
166])
167
168# The guts of gl_CHECK_NEXT_HEADERS and gl_NEXT_HEADERS.
169AC_DEFUN([gl_NEXT_HEADERS_INTERNAL],
170[
171 AC_REQUIRE([gl_INCLUDE_NEXT])
172 AC_REQUIRE([AC_CANONICAL_HOST])
173
174 m4_if([$2], [check],
175 [AC_CHECK_HEADERS_ONCE([$1])
176 ])
177
178 m4_foreach_w([gl_HEADER_NAME], [$1],
179 [AS_VAR_PUSHDEF([gl_next_header],
180 [gl_cv_next_]m4_defn([gl_HEADER_NAME]))
181 if test $gl_cv_have_include_next = yes; then
182 AS_VAR_SET([gl_next_header], ['<'gl_HEADER_NAME'>'])
183 else
184 AC_CACHE_CHECK(
185 [absolute name of <]m4_defn([gl_HEADER_NAME])[>],
186 m4_defn([gl_next_header]),
187 [m4_if([$2], [check],
188 [AS_VAR_PUSHDEF([gl_header_exists],
189 [ac_cv_header_]m4_defn([gl_HEADER_NAME]))
190 if test AS_VAR_GET(gl_header_exists) = yes; then
191 AS_VAR_POPDEF([gl_header_exists])
192 ])
193 AC_LANG_CONFTEST(
194 [AC_LANG_SOURCE(
195 [[#include <]]m4_dquote(m4_defn([gl_HEADER_NAME]))[[>]]
196 )])
197 dnl AIX "xlc -E" and "cc -E" omit #line directives for header
198 dnl files that contain only a #include of other header files and
199 dnl no non-comment tokens of their own. This leads to a failure
200 dnl to detect the absolute name of <dirent.h>, <signal.h>,
201 dnl <poll.h> and others. The workaround is to force preservation
202 dnl of comments through option -C. This ensures all necessary
203 dnl #line directives are present. GCC supports option -C as well.
204 case "$host_os" in
205 aix*) gl_absname_cpp="$ac_cpp -C" ;;
206 *) gl_absname_cpp="$ac_cpp" ;;
207 esac
208 dnl eval is necessary to expand gl_absname_cpp.
209 dnl Ultrix and Pyramid sh refuse to redirect output of eval,
210 dnl so use subshell.
211 AS_VAR_SET([gl_next_header],
212 ['"'`(eval "$gl_absname_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
213 sed -n '\#/]m4_defn([gl_HEADER_NAME])[#{
214 s#.*"\(.*/]m4_defn([gl_HEADER_NAME])[\)".*#\1#
215 s#^/[^/]#//&#
216 p
217 q
218 }'`'"'])
219 m4_if([$2], [check],
220 [else
221 AS_VAR_SET([gl_next_header], ['<'gl_HEADER_NAME'>'])
222 fi
223 ])
224 ])
225 fi
226 AC_SUBST(
227 AS_TR_CPP([NEXT_]m4_defn([gl_HEADER_NAME])),
228 [AS_VAR_GET([gl_next_header])])
229 if test $gl_cv_have_include_next = yes || test $gl_cv_have_include_next = buggy; then
230 # INCLUDE_NEXT_AS_FIRST_DIRECTIVE='include_next'
231 gl_next_as_first_directive='<'gl_HEADER_NAME'>'
232 else
233 # INCLUDE_NEXT_AS_FIRST_DIRECTIVE='include'
234 gl_next_as_first_directive=AS_VAR_GET([gl_next_header])
235 fi
236 AC_SUBST(
237 AS_TR_CPP([NEXT_AS_FIRST_DIRECTIVE_]m4_defn([gl_HEADER_NAME])),
238 [$gl_next_as_first_directive])
239 AS_VAR_POPDEF([gl_next_header])])
240])
241
242# Autoconf 2.68 added warnings for our use of AC_COMPILE_IFELSE;
243# this fallback is safe for all earlier autoconf versions.
244m4_define_default([AC_LANG_DEFINES_PROVIDED])
generated by cgit v1.2.3 (git 2.39.1) at 2024-04-18 14:56:15 +0000