libgnunettesting_src = [
                        'testing_api_cmd_barrier.c',
                        'testing_api_cmd_barrier_reached.c',
                        'testing_api_cmd_finish.c',
                        'testing_api_cmd_local_test_prepared.c',
                        'testing_api_cmd_send_peer_ready.c',
                        'testing_api_cmd_block_until_external_trigger.c',
                        'testing_api_cmd_netjail_start.c',
                        'testing_api_cmd_netjail_start_cmds_helper.c',
                        'testing_api_cmd_netjail_stop_cmds_helper.c',
                        'testing_api_cmd_netjail_stop.c',
                        'testing.c',
                        'testing_api_cmd_system_create.c',
                        'testing_api_cmd_system_destroy.c',
                        'testing_api_cmd_batch.c',
                        'testing_api_loop.c',
                        'testing_api_traits.c'
                        ]

gnunettesting_src = ['gnunet-testing.c']
gnunetservicetesting_src = ['gnunet-service-testing.c']

configure_file(input : 'testing.conf',
               output : 'testing.conf',
               configuration : cdata,
               install: true,
               install_dir: pkgcfgdir)


if get_option('monolith')
  foreach p : libgnunettesting_src
    gnunet_src += 'testing/' + p
  endforeach
  subdir_done()
endif

libgnunettesting = library('gnunettesting',
        libgnunettesting_src,
        soversion: '0',
        version: '0.1.0',
        dependencies: [libgnunetutil_dep,
                       m_dep,
                       libgnunetarm_dep],
        include_directories: [incdir, configuration_inc],
        install: true,
        install_dir: get_option('libdir'))
libgnunettesting_dep = declare_dependency(link_with : libgnunettesting)
pkg.generate(libgnunettesting, url: 'https://www.gnunet.org',
             description : 'Provides API for storing GNS records to a database')

executable ('gnunet-testing',
          gnunettesting_src,
          dependencies: [libgnunettesting_dep,
                         libgnunetutil_dep,
                         ],
          include_directories: [incdir, configuration_inc],
        install: true,
        install_dir: get_option('bindir'))