how come httpd2psyc was missing?

1 files changed, 230 insertions, 0 deletions

diff --git a/bin/httpd2psyc b/bin/httpd2psyc
new file mode 100755
index 0000000..0875c14
--- /dev/null
+++ b/bin/httpd2psyc
@@ -0,0 +1,230 @@
+#!/usr/local/bin/perl -I/usr/depot/lib/perl5
+
+sub debug() { 0 }
+sub chat() { 1 }
+
+use IO::Socket;
+use POSIX qw( mkfifo );                 # optional, for -s option
+use Pod::Usage qw( pod2usage );
+use Term::ANSIColor qw( :constants );   # optional but pervasive
+use Net::PSYC qw( :event );             # needed for event loop
+use Getopt::Std qw( getopt );
+getopt('timbls');
+
+my $bind = $opt_b || "psyc://$ENV{USER}\@127.0.0.1:4088/\$httpd";
+my $target = $opt_t || "psyc://127.0.0.1:4404/\@httpd";
+
+
+## SANDWICHES ##
+
+sub say {
+        print BOLD, GREEN, @_, RESET, "\n";
+}
+
+sub reallyquit { exit; }
+sub quit {
+        # error condition can be triggered several times
+        return if $quitting++;
+        tellpsyc(chat? "_request_leave_httpd": "_notice_stopping_httpd", "[_command] stopping on [_nick].");
+        tellpsyc("_request_circuit_shutdown", "Seeyasoon.");
+        add(2, 't', \&reallyquit);
+}
+
+sub tellpsyc {
+        my ($mc, $text, $var, $value) = @_;
+        say "tellpsyc: ", $text if debug & 4;
+        return unless $target;
+        if (length $text > 1000) {
+                $mc = "_error_excessive_data$mc";
+                $text = "[_amount_data] bytes of excess data ignored. Check console.";
+                $var = "_amount_data";
+                $value = length $text;
+        }
+        sendmsg($target, $mc, $text, $value? { $var => $value } : \%pv);
+}
+
+sub fifoerror {
+        return if $quitting;
+        my $msg = "FIFO error: $_";
+        say $msg;
+        tellpsyc('_notice_warning_httpd', $msg);
+        if ($opt_d) {
+                sleep 7;
+                goto REOPEN;
+        }
+        return &quit;
+}
+
+sub fifoparse {
+        $_ = <$fifo>;
+        chomp; chomp;
+        say "fifoparse($!): $_" if debug & 1;
+        fifoerror unless $_;
+        print $log $_, "\n" if $log;
+        # if httpd is giving us non-json input, we just send it as is
+        unless ( /^{ (.*)},$/ ) {
+                tellpsyc('_notice_access_httpd_raw', $_);
+                return;
+        }
+        $_ = $1;
+        @_ = split( /"([^"]*)":"([^"]*)", / );
+        my %m = %pv;
+        while (@_) {
+                $e = shift; $k = shift; $v = shift;
+                print STDERR "JSON parse error: '$e' in { $_ }" if $e;
+                print "\t", GREEN, $k, RESET, "\t", $v, "\n" if debug & 8;
+                $m{$k} = $v;
+        }
+        $m{_network_traffic} = $m{_network_traffic_incoming} + $m{_network_traffic_outgoing};
+        # only forward to psyced when not a transfer continuation
+#       if ( $m{_status_HTTP} eq 206 ) {
+#               print CYAN, " +", $m{_network_traffic}, " ", RESET;
+#               return;
+#       }
+#       print RED, "_", RESET;
+        print BOLD, $m{_status_HTTP}, "   ", CYAN, $m{_network_address_IP}, "\t",
+              RESET, $m{_network_traffic}, "\t", BOLD, YELLOW, $m{_item_path},
+              " ", GREEN, $m{_version_agent_HTTP}, RESET, "\n";
+        # only forward messages about large files...... YMMV
+        return if $opt_s and $m{_network_traffic} < $opt_s || $m{_status_HTTP} eq 206;
+        sendmsg($target, '_notice_access_httpd', "[_network_address_IP] fetches [_item_path] ([_network_traffic] bytes) using [_version_agent_HTTP]", \%m);
+}
+
+sub keyparse {
+        $_ = <STDIN>;
+        say "keyparse: ", $_ if debug & 2;
+        return &quit if /^\s*q\s*$/i;
+        return system('/usr/bin/clear') if /^\.$/;
+                # should be _converse
+        return tellpsyc("_message_public", $1) if m!^\s*/\s+(.*\S.*)$!;
+}
+
+sub msg {
+        my ($source, $mc, $data, $vars) = @_;
+        say "psyc: $mc from $source" if debug & 4;
+        if ($mc =~ /^_(message|converse)/) {
+                # message echo will pass through here. legitimate users of
+                # your PSYC server can send a message back to the localhost
+                # process, so you may see an answer from somebody.
+                if (exists $vars->{_nick}) {
+                        $_ = "<". $vars->{_nick} ."> ". YELLOW . $data;
+                } else {
+                        $_ = "(". $source .") ". YELLOW . $data;
+                }
+        } elsif (chat and $mc =~ /^_notice.*_httpd/) {
+                return; # do not display our own notices
+        } else {
+                $_ = psyctext($data, $vars);
+        }
+        print BOLD, MAGENTA, $_, RESET, "\n";
+}
+
+sub idlebilly {
+        tellpsyc('_notice_warning_idle_httpd', "[_command] has detected idling [_nick] httpd.");
+}
+
+sub mkdirhier {
+        my $d = shift;
+        if (-d $d) {
+#               print STDERR BLUE, "(directory $d already exists)\n", RESET;
+        } else {
+                if (system('/bin/mkdir', '-p', $d)) {
+                        undef $!;
+                        die "Could not make directory hierarchy: $!"
+                            if system('mkdirhier', $d);
+                }
+        }
+}
+
+## MAIN ###
+
+        say "httpd2psyc - a real-time httpd log analyzer with PSYC notification";
+        $nick = shift || 'default';
+        if ($opt_h) {
+                pod2usage;
+        }
+
+        $pv{_nick} = $nick;
+        $pv{_command} = $0;
+        bind_uniform( $bind );
+        register_uniform();
+        say "Listening for PSYC controls on $bind";
+        say "Sending PSYC notifications to $target";
+
+        $|=1;
+
+        $fifopath = $opt_m || "/var/run/httpd.fifo";
+        if (not -p $fifopath) {
+                $fifopath =~ m#(.*)/[^/]+$#;
+                mkdirhier( $1 ) if $1;
+                undef $!;
+                die "Could not mkfifo $fifopath $!" unless mkfifo $fifopath, 0600;
+#               system('chgrp', 'www', $fifopath);
+#               chmod 0660, $fifopath;
+        }
+        say "Monitoring $fifopath for HTTP events";
+REOPEN:
+        if (open($fifo, $fifopath)) {
+                add($fifo, 'r', \&fifoparse);
+                add($fifo, 'e', \&fifoerror);
+        } else {
+                die "Cannot read from $fifopath: $!";
+        }
+        die "Cannot write to $opt_l: $!"
+            if $opt_l and not open($log, '>>', $opt_l);
+        add(\*STDIN, 'r', \&keyparse);
+        add($opt_i, 'i', \&idlebilly) if $opt_i;
+        tellpsyc(chat? "_request_enter_httpd": "_notice_starting_httpd", "[_command] starting on [_nick].");
+        start_loop();
+        exit;
+
+__END__
+
+=pod
+
+=head1 NAME
+
+httpd2psyc - a real-time httpd log analyzer with PSYC notification
+
+=head1 SYNOPSIS
+
+ httpd2psyc [<options>] [<nickname>]
+ 
+ Options:
+   -m <path>      (m)onitor a FIFO for interesting HTTP events
+   -t <uniform>   PSYC (t)arget address to send notifications to
+   -d             (D)aemon: reopen FIFO whenever httpd closes it (on restart)
+   -s <bytes>     Threshold of traffic (s)ize before forwarding is triggered
+   -b <uniform>   PSYC address to (b)ind to
+   -l <logfile>   Keep a transaction (l)og - BEWARE OF GDPR!
+   -i <seconds>   Send a PSYC warning if httpd has been (i)dle too long
+ 
+=head1 DESCRIPTION
+
+HTTP logfile to PSYC gateway. Works by sending httpd logfile output
+into a FIFO and having this script pick it up. For optimal rendering
+you should configure your httpd to output JSON-PSYC format, using
+something like this:
+
+    LogFormat "{ \"_time_JSON\":\"%{%Y-%m-%d}tT%{%T}t.%{msec_frac}tZ\", \"_system_process\":\"%D\", \"_item_size\":\"%B\", \"_item_path\":\"%f\", \"_network_address_IP\":\"%a\", \"_site_HTTP\":\"%V\", \"_request_HTTP\":\"%U\", \"_query_HTTP\":\"%q\", \"_method_HTTP\":\"%m\", \"_status_HTTP\":\"%>s\", \"_version_agent_HTTP\":\"%{User-agent}i\", \"_uniform_referrer\":\"%{Referer}i\", \"_network_traffic_incoming\":\"%I\", \"_network_traffic_outgoing\":\"%O\", }," jsonpsyc
+    CustomLog /var/run/httpd.fifo jsonpsyc
+
+You should run 'httpd2psyc -m /var/run/httpd.fifo' first so that
+it takes care of mkfifo.
+
+=head1 PRIVACY
+
+Remember that you are not supposed to store any IP numbers or other 
+personal data if you intend to be GDPR compliant. This is just for 
+realtime monitoring.
+
+=head1 AUTHORS
+
+carlo von lynX.
+
+=head1 COPYRIGHT
+
+This program is free software, published under the Affero GNU Public
+License. A disclaimer isn't necessary in my country, nor do I need
+to mention the current year to assert a copyright.
+