anastasis

Credential backup and recovery protocol and service
Log | Files | Refs | Submodules | README | LICENSE

meson.build (2667B)

      1 # This file is in the public domain
      2 libanastasistesting_SOURCES = [
      3     'testing_api_cmd_policy_store.c',
      4     'testing_api_cmd_truth_challenge.c',
      5     'testing_api_cmd_truth_solve.c',
      6     'testing_api_cmd_truth_store.c',
      7     'testing_api_cmd_policy_lookup.c',
      8     'testing_api_cmd_config.c',
      9     'testing_api_helpers.c',
     10     'testing_api_traits.c',
     11     'testing_cmd_truth_upload.c',
     12     'testing_cmd_policy_create.c',
     13     'testing_cmd_secret_share.c',
     14     'testing_cmd_recover_secret.c',
     15     'testing_cmd_challenge_answer.c',
     16 ]
     17 libanastasistesting = library(
     18     'anastasistesting',
     19     libanastasistesting_SOURCES,
     20     soversion: solibversions['libanastasistesting']['soversion'],
     21     version: solibversions['libanastasistesting']['soversion'],
     22     install_rpath: rpath_option,
     23     dependencies: [
     24         libanastasis_dep,
     25         libanastasisrest_dep,
     26         talerexchange_dep,
     27         talermerchant_dep,
     28         talerjson_dep,
     29         talerutil_dep,
     30         gnunetutil_dep,
     31         gnunetcurl_dep,
     32         gnunetjson_dep,
     33         json_dep,
     34         talertesting_dep,
     35         libanastasisutil_dep,
     36     ],
     37     include_directories: [incdir, configuration_inc],
     38     install: true,
     39     install_dir: get_option('libdir'),
     40 )
     41 
     42 libanastasistesting_dep = declare_dependency(link_with: libanastasistesting)
     43 pkg.generate(
     44     libanastasistesting,
     45     url: 'https://taler.net',
     46     description: 'GNU Taler anastasis testing library',
     47 )
     48 
     49 
     50 test_anastasisrest_api = executable(
     51     'test_anastasisrest_api',
     52     ['test_anastasis_api.c'],
     53     dependencies: [
     54         libanastasistesting_dep,
     55         talermerchanttesting_dep,
     56         talertesting_dep,
     57         gnunetutil_dep,
     58         json_dep,
     59     ],
     60     include_directories: [incdir, configuration_inc],
     61     install: false,
     62 )
     63 test(
     64     'test_anastasisrest_api',
     65     test_anastasisrest_api,
     66     workdir: meson.current_build_dir(),
     67     suite: ['testing'],
     68     is_parallel: false,
     69     timeout: 300,
     70 )
     71 
     72 
     73 
     74 test_anastasis = executable(
     75     'test_anastasis',
     76     ['test_anastasis.c'],
     77     dependencies: [
     78         libanastasistesting_dep,
     79         talermerchanttesting_dep,
     80         talertesting_dep,
     81         talerexchange_dep,
     82         gnunetutil_dep,
     83         json_dep,
     84     ],
     85     include_directories: [incdir, configuration_inc],
     86     install: false,
     87 )
     88 test(
     89     'test_anastasis',
     90     test_anastasis,
     91     workdir: meson.current_build_dir(),
     92     suite: ['testing'],
     93     is_parallel: false,
     94     timeout: 300,
     95 )
     96 
     97 
     98 
     99 EXTRA_DIST = ['test_anastasis_api.conf', 'sms_authentication.sh']
    100 foreach f : EXTRA_DIST
    101     configure_file(input: f, output: f, copy: true)
    102 endforeach
    103 
    104 subdir('test_anastasis_api_home' / 'taler' / 'exchange' / 'offline-keys')