anastasis

Credential backup and recovery protocol and service
Log | Files | Refs | Submodules | README | LICENSE

meson.build (1856B)

      1 # This file is in the public domain
      2 install_data('paths.conf', install_dir: pkgcfgdir)
      3 
      4 libanastasisutil_SOURCES = ['anastasis_crypto.c', 'os_installation.c', 'pin.c']
      5 
      6 libanastasisutil = library(
      7     'anastasisutil',
      8     libanastasisutil_SOURCES,
      9     soversion: solibversions['libanastasisutil']['soversion'],
     10     version: solibversions['libanastasisutil']['soversion'],
     11     install_rpath: rpath_option,
     12     dependencies: [
     13         gnunetutil_dep,
     14         gnunetjson_dep,
     15         gcrypt_dep,
     16         talerutil_dep,
     17         sodium_dep,
     18         json_dep,
     19     ],
     20     include_directories: [incdir, configuration_inc],
     21     install: true,
     22     install_dir: get_option('libdir'),
     23 )
     24 
     25 libanastasisutil_dep = declare_dependency(link_with: libanastasisutil)
     26 pkg.generate(
     27     libanastasisutil,
     28     url: 'https://taler.net',
     29     description: 'GNU Taler anastasis utilities library',
     30 )
     31 
     32 executable(
     33     'anastasis-config',
     34     ['anastasis-config.c'],
     35     dependencies: [libanastasisutil_dep, gnunetutil_dep],
     36     include_directories: [incdir, configuration_inc],
     37     install: true,
     38 )
     39 
     40 
     41 test_anastasis_crypto = executable(
     42     'test_anastasis_crypto',
     43     ['test_anastasis_crypto.c'],
     44     dependencies: [
     45       gnunetutil_dep,
     46       talerutil_dep,
     47       libanastasisutil_dep,
     48       json_dep,
     49     ],
     50     include_directories: [incdir, configuration_inc],
     51     build_by_default: false,
     52     install: false,
     53 )
     54 test(
     55     'test_anastasis_crypto',
     56     test_anastasis_crypto,
     57     workdir: meson.current_build_dir(),
     58     suite: ['util'],
     59     is_parallel: false,
     60 )
     61 
     62 executable(
     63     'anastasis-crypto-tvg',
     64     ['anastasis-crypto-tvg.c'],
     65     dependencies: [
     66         libanastasisutil_dep,
     67         gnunetutil_dep,
     68         gnunetjson_dep,
     69         json_dep,
     70         talerutil_dep,
     71         talerjson_dep,
     72     ],
     73     include_directories: [incdir, configuration_inc],
     74     install: true,
     75 )