sync

Backup service to store encrypted wallet databases (experimental)
Log | Files | Refs | Submodules | README | LICENSE

meson.build (1663B)

      1 # This build file is in the public domain
      2 configure_file(
      3     input: 'paths.conf',
      4     output: 'paths.conf',
      5     configuration: cdata,
      6     install: true,
      7     install_dir: pkgcfgdir,
      8 )
      9 
     10 
     11 libsyncutil = library(
     12     'syncutil',
     13     ['os_installation.c', 'sync_signatures.c', 'sync_block.c', 'sync_object.c'],
     14     soversion: solibversions['libsyncutil']['soversion'],
     15     version: solibversions['libsyncutil']['soversion'],
     16     install_rpath: rpath_option,
     17     dependencies: [
     18         gnunetutil_dep,
     19         talerutil_dep,
     20         gnunetjson_dep,
     21         talerjson_dep,
     22         json_dep,
     23     ],
     24     include_directories: [incdir, configuration_inc],
     25     install: true,
     26     install_dir: get_option('libdir'),
     27 )
     28 
     29 libsyncutil_dep = declare_dependency(link_with: libsyncutil)
     30 pkg.generate(
     31     libsyncutil,
     32     url: 'https://taler.net',
     33     description: 'GNU Taler sync utilities library',
     34 )
     35 
     36 executable(
     37     'sync-config',
     38     ['sync-config.c'],
     39     dependencies: [libsyncutil_dep, gnunetutil_dep],
     40     include_directories: [incdir, configuration_inc],
     41     install: true,
     42 )
     43 
     44 
     45 test_sync_signatures = executable(
     46     'test_sync_signatures',
     47     ['test_sync_signatures.c'],
     48     install_rpath: rpath_option,
     49     dependencies: [
     50         libsyncutil_dep,
     51         talerutil_dep,
     52         gnunetutil_dep,
     53         gnunetjson_dep,
     54         json_dep,
     55     ],
     56     include_directories: [incdir, configuration_inc],
     57     install: false,
     58 )
     59 # Not in 'installcheck', which the default test setup excludes: this
     60 # test needs neither an installed tree nor a database.
     61 test(
     62     'test_sync_signatures',
     63     test_sync_signatures,
     64     workdir: meson.current_build_dir(),
     65     suite: ['util'],
     66 )
     67 
     68