commit ec06f9f27d392ea27afbb248782eb0c43d05eef3
parent 2b93b4ad289ecc237cdcfbd853577320197611f3
Author: Martin Schanzenbach <schanzen@gnunet.org>
Date: Sun, 12 Apr 2026 14:09:44 +0200
build: remove autotools files
Diffstat:
19 files changed, 0 insertions(+), 2037 deletions(-)
diff --git a/Makefile.am b/Makefile.am
@@ -1,23 +0,0 @@
-# This Makefile is in the public domain
-
-if DOC_ONLY
-if ENABLE_DOC
- SUBDIRS = . doc
-else
- SUBDIRS = .
-endif
-else
-if ENABLE_DOC
- SUBDIRS = . src doc contrib
-else
- SUBDIRS = . src doc contrib
-endif
-endif
-
-@DX_RULES@
-
-ACLOCAL_AMFLAGS = -I m4
-EXTRA_DIST = \
- AUTHORS \
- COPYING.AGPL \
- Doxyfile
diff --git a/configure.ac b/configure.ac
@@ -1,326 +0,0 @@
-# -*- Autoconf -*-
-# Process this file with autoconf to produce a configure script.
-#
-# This configure file is in the public domain
-
-AC_PREREQ([2.69])
-AC_INIT([sync],[1.5.1],[taler-bug@gnu.org])
-AC_CONFIG_SRCDIR([src/sync/sync-httpd.c])
-AC_CONFIG_HEADERS([sync_config.h])
-# support for non-recursive builds
-AM_INIT_AUTOMAKE([subdir-objects 1.9 tar-pax])
-
-# pretty build rules
-AM_SILENT_RULES([yes])
-
-AC_CONFIG_MACRO_DIR([m4])
-AC_PROG_AWK
-AC_PROG_CC
-AC_PROG_OBJC
-AC_PROG_INSTALL
-AC_PROG_LN_S
-AC_PROG_MAKE_SET
-AM_PROG_CC_C_O
-
-LT_INIT([disable-static])
-
-
-DX_INIT_DOXYGEN([sync],,,
-DX_PS_FEATURE(OFF),
-DX_PDF_FEATURE(OFF),
-DX_RTF_FEATURE(OFF),
-DX_CHI_FEATURE(OFF),
-DX_XML_FEATURE(OFF))
-
-
-AC_CHECK_PROG([DPKG_ARCH], [dpkg-architecture], [yes], [no])
-if test "x$DPKG_ARCH" = "xyes"; then
- MULTIARCH=`dpkg-architecture -qDEB_HOST_MULTIARCH`
-else
- MULTIARCH=""
-fi
-
-AC_MSG_CHECKING([whether to compile documentation ONLY])
-AC_ARG_ENABLE([only-doc],
- [AS_HELP_STRING([--enable-only-doc], [only compile Taler documentation])],
- [doc_only=${enableval}],
- [doc_only=no])
-AC_MSG_RESULT($doc_only)
-AM_CONDITIONAL([DOC_ONLY], [test "$doc_only" = "yes"])
-
-
-# Not indented as it covers most of the file...
-AS_IF([test "x$doc_only" != xyes],[
-
-
-# Checks for programs.
-AC_PROG_CC
-
-# Force some CFLAGS
-CFLAGS="-Wall -Wno-address-of-packed-member $CFLAGS"
-
-# Checks for header files.
-AC_CHECK_HEADERS([stdint.h stdlib.h string.h unistd.h])
-
-
-# Check for Taler's libtalermerchant
-libtalermerchant=0
-AC_MSG_CHECKING([for libtalermerchant])
-AC_ARG_WITH(merchant,
- [AS_HELP_STRING([--with-merchant=PFX], [base of Taler MERCHANT installation])],
- [AC_MSG_RESULT([given as $with_merchant])],
- [AC_MSG_RESULT(not given)
- with_merchant=yes])
-AS_CASE([$with_merchant],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-merchant is required])],
- [LDFLAGS="-L$with_merchant/lib/$MULTIARCH -L$with_merchant/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_merchant/include $CPPFLAGS $POSTGRESQL_CPPFLAGS"])
-
-AC_CHECK_HEADERS([taler/taler_merchant_service.h],
- [AC_CHECK_LIB([talermerchant], [TALER_MERCHANT_poll_payment], libtalermerchant=1)],
- [], [])
-
-
-# Check for GNUnet's libgnunetutil.
-libgnunetutil=0
-AC_MSG_CHECKING([for libgnunetutil])
-AC_ARG_WITH(gnunet,
- [AS_HELP_STRING([--with-gnunet=PFX], [base of GNUnet installation])],
- [AC_MSG_RESULT([given as $with_gnunet])],
- [AC_MSG_RESULT(not given)
- with_gnunet=yes])
-AS_CASE([$with_gnunet],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-gnunet is required])],
- [LDFLAGS="-L$with_gnunet/lib/$MULTIARCH -L$with_gnunet/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_gnunet/include $CPPFLAGS"])
-AC_CHECK_HEADERS([gnunet/gnunet_util_lib.h],
- [AC_CHECK_LIB([gnunetutil], [GNUNET_SCHEDULER_run], libgnunetutil=1)])
-AS_IF([test $libgnunetutil != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libgnunetutil to build this program.
-*** This library is part of GNUnet, available at
-*** https://gnunet.org
-*** ]])])
-
-
-AC_CHECK_HEADERS([taler/taler_mhd_lib.h],
- [AC_CHECK_LIB([talermhd], [TALER_MHD_listen_bind], libtalermhd=1)])
-AM_CONDITIONAL(HAVE_TALERMHD, test x$libtalermhd = x1)
-AS_IF([test $libtalermhd != 1],
- [AC_MSG_ERROR([[
-***
-*** You need libtalermhd >= 1.1.0 (API v6) to build this program.
-*** This library is part of the GNU Taler exchange, available at
-*** https://taler.net
-*** ]])])
-
-
-
-# test for postgres
-AX_LIB_POSTGRESQL([15])
-AS_IF([test "x$found_postgresql" = "xyes"],[postgres=true])
-AM_CONDITIONAL(HAVE_POSTGRESQL, test x$postgres = xtrue)
-
-SYNC_LIB_LDFLAGS="-export-dynamic -no-undefined"
-SYNC_PLUGIN_LDFLAGS="-export-dynamic -avoid-version -module -no-undefined"
-
-AC_SUBST(SYNC_LIB_LDFLAGS)
-AC_SUBST(SYNC_PLUGIN_LDFLAGS)
-
-# Check for Taler's libtalerpq
-libtalerpq=0
-AC_MSG_CHECKING([for libtalerpq])
-AC_ARG_WITH(exchange,
- [AS_HELP_STRING([--with-exchange=PFX], [base of Taler EXCHANGE installation])],
- [AC_MSG_RESULT([given as $with_exchange])],
- [AC_MSG_RESULT(not given)
- with_exchange=yes])
-AS_CASE([$with_exchange],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-exchange is required])],
- [LDFLAGS="-L$with_exchange/lib/$MULTIARCH -L$with_exchange/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_exchange/include $CPPFLAGS $POSTGRESQL_CPPFLAGS"])
-
-CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
-
-AC_CHECK_HEADERS([gnunet/gnunet_pq_lib.h],
- [AC_CHECK_LIB([gnunetpq], [GNUNET_PQ_connect_with_cfg], libgnunetpq=1)])
-AM_CONDITIONAL(HAVE_GNUNETPQ, test x$libgnunetpq = x1)
-
-
-
-
-# check for libmicrohttpd
-microhttpd=0
-AC_MSG_CHECKING([for microhttpd])
-AC_ARG_WITH([microhttpd],
- [AS_HELP_STRING([--with-microhttpd=PFX], [base of microhttpd installation])],
- [AC_MSG_RESULT([given as $with_microhttpd])],
- [AC_MSG_RESULT([not given])
- with_microhttpd=yes])
-AS_CASE([$with_microhttpd],
- [yes], [],
- [no], [AC_MSG_ERROR([--with-microhttpd is required])],
- [LDFLAGS="-L$with_microhttpd/lib/$MULTIARCH -L$with_microhttpd/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_microhttpd/include $CPPFLAGS"])
-AC_CHECK_LIB(microhttpd,MHD_start_daemon,
- [AC_CHECK_HEADER([microhttpd.h],[microhttpd=1])])
-AS_IF([test $microhttpd = 0],
- [AC_MSG_ERROR([[
-***
-*** You need libmicrohttpd to build this program.
-*** ]])])
-
-
-# check for libmicrohttpd2
-AC_MSG_CHECKING([for microhttpd2])
-AC_ARG_WITH([microhttpd2],
- [AS_HELP_STRING([--with-microhttpd2=PFX], [base of libmicrohttpd2 installation])],
- [AC_MSG_RESULT([given as $with_microhttpd2])],
- [AC_MSG_RESULT([not given])
- with_microhttpd2=yes])
-AS_CASE([$with_microhttpd2],
- [yes],[],
- [no],[],
- [LDFLAGS="-L$with_microhttpd2/lib/$MULTIARCH -L$with_microhttpd2/lib/ $LDFLAGS"
- CPPFLAGS="-I$with_microhttpd2/include $CPPFLAGS"])
-MHD2_VERSION_AT_LEAST([1.99.0])
-
-
-
-jansson=0
-PKG_CHECK_MODULES([JANSSON], [jansson >= 2.3],
- [LDFLAGS="$JANSSON_LIBS $LDFLAGS"
- CPPFLAGS="$JANSSON_CFLAGS $CPPFLAGS"],
- [AC_MSG_ERROR([[
-***
-*** You need libjansson to build this program.
-***]])])
-
-# libcurl-gnutls
-AC_CHECK_LIB([curl],
- [curl_easy_getinfo],
- [LIBCURL="-lcurl"
- curl_gnutls=1],
- [curl_gnutls=0])
-LIBCURL_CHECK_CONFIG([],[7.34.0],[curl=true],[curl=false])
-# Check for curl/curl.h
-AC_CHECK_HEADERS([curl/curl.h],,
- curl=false)
-
-AS_IF([test x$curl = xfalse],
- [AC_MSG_ERROR([sync requires libcurl-gnutls >= 7.34])])
-
-# gcov compilation
-AC_MSG_CHECKING(whether to compile with support for code coverage analysis)
-AC_ARG_ENABLE([coverage],
- AS_HELP_STRING([--enable-coverage],
- [compile the library with code coverage support]),
- [use_gcov=${enableval}],
- [use_gcov=no])
-AC_MSG_RESULT($use_gcov)
-AM_CONDITIONAL([USE_COVERAGE], [test "x$use_gcov" = "xyes"])
-
-# Require minimum libgcrypt version
-need_libgcrypt_version=1.6.1
-AC_DEFINE_UNQUOTED([NEED_LIBGCRYPT_VERSION], ["$need_libgcrypt_version"],
- [minimum version of libgcrypt required])
-AM_PATH_LIBGCRYPT([$need_libgcrypt_version])
-
-# logging
-extra_logging=0
-AC_ARG_ENABLE([logging],
- AS_HELP_STRING([--enable-logging@<:@=value@:>@],[Enable logging calls. Possible values: yes,no,verbose ('yes' is the default)]),
- [AS_IF([test "x$enableval" = "xyes"], [],
- [test "x$enableval" = "xno"], [AC_DEFINE([GNUNET_CULL_LOGGING],[],[Define to cull all logging calls])],
- [test "x$enableval" = "xverbose"], [extra_logging=1]
- [test "x$enableval" = "xveryverbose"], [extra_logging=2])
- ], [])
-AC_DEFINE_UNQUOTED([GNUNET_EXTRA_LOGGING],[$extra_logging],[1 if extra logging is enabled, 2 for very verbose extra logging, 0 otherwise])
-
-# version info
-AC_PATH_PROG(gitcommand, git)
-AC_MSG_CHECKING(for source being under a VCS)
-git_version=
-AS_IF([test ! "X$gitcommand" = "X"],
-[
- git_version=$(cd $srcdir ; git rev-list --full-history --all --abbrev-commit | head -n 1 2>/dev/null)
-])
-AS_IF([test "X$git_version" = "X"],
- [
- vcs_name="no"
- vcs_version="\"release\""
- ],
- [
- vcs_name="yes, git-svn"
- vcs_version="\"git-$git_version\""
- ])
-AC_MSG_RESULT($vcs_name)
-
-AC_MSG_CHECKING(VCS version)
-AC_MSG_RESULT($vcs_version)
-AC_DEFINE_UNQUOTED(VCS_VERSION, [$vcs_version], [VCS revision/hash or tarball version])
-
-# Checks for typedefs, structures, and compiler characteristics.
-AC_TYPE_PID_T
-AC_TYPE_SIZE_T
-AC_TYPE_UINT16_T
-AC_TYPE_UINT32_T
-AC_TYPE_UINT64_T
-AC_TYPE_INTMAX_T
-AC_TYPE_UINTMAX_T
-
-# Checks for library functions.
-AC_CHECK_FUNCS([strdup])
-
-
-AC_ARG_ENABLE([[doc]],
- [AS_HELP_STRING([[--disable-doc]], [do not build any documentation])], ,
- [enable_doc=yes])
-test "x$enable_doc" = "xno" || enable_doc=yes
-AM_CONDITIONAL([ENABLE_DOC], [test "x$enable_doc" = "xyes"])
-
-
-],[ # this is about the doc-only if on top of the file
-
-# logic if doc_only is set, make sure conditionals are still defined
-AM_CONDITIONAL([HAVE_MHD2], [false])
-AM_CONDITIONAL([HAVE_GNUNETPQ], [false])
-AM_CONDITIONAL([HAVE_POSTGRESQL], [false])
-AM_CONDITIONAL([HAVE_TALERMHD], [false])
-AM_CONDITIONAL([USE_COVERAGE], [false])
-AM_CONDITIONAL([ENABLE_DOC], [true])
-
-
-# end of 'doc_only'
-])
-
-
-# should experimental code be compiled (code that may not yet compile / have passing test cases)?
-AC_MSG_CHECKING(whether to compile experimental code)
-AC_ARG_ENABLE([experimental],
- [AS_HELP_STRING([--enable-experimental], [enable compiling experimental code])],
- [enable_experimental=${enableval}],
- [enable_experimental=no])
-AC_MSG_RESULT($enable_experimental)
-AM_CONDITIONAL([HAVE_EXPERIMENTAL], [test "x$enable_experimental" = "xyes"])
-
-
-AC_CONFIG_FILES([Makefile
-contrib/Makefile
-doc/Makefile
-doc/doxygen/Makefile
-src/Makefile
-src/include/Makefile
-src/include/sync/Makefile
-src/include/sync/sync-database/Makefile
-src/lib/Makefile
-src/util/Makefile
-src/sync/Makefile
-src/syncdb/Makefile
-src/testing/Makefile
-])
-AC_OUTPUT
diff --git a/contrib/Makefile.am b/contrib/Makefile.am
@@ -1,14 +0,0 @@
-# This file is in the public domain.
-
-SUBDIRS = .
-
-bin_SCRIPTS = \
- sync-dbconfig
-
-EXTRA_DIST = \
- $(bin_SCRIPTS) \
- gnunet.tag \
- microhttpd.tag \
- taler-exchange.tag \
- uncrustify.cfg \
- uncrustify_precommit
diff --git a/doc/Makefile.am b/doc/Makefile.am
@@ -1,13 +0,0 @@
-# This Makefile is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-SUBDIRS = . doxygen
-
-man_MANS = \
- prebuilt/man/sync-config.1 \
- prebuilt/man/sync-dbconfig.1 \
- prebuilt/man/sync-dbinit.1 \
- prebuilt/man/sync-httpd.1 \
- prebuilt/man/sync.conf.5
-
-EXTRA_DIST = \
- $(man_MANS)
diff --git a/doc/doxygen/Makefile.am b/doc/doxygen/Makefile.am
@@ -1,18 +0,0 @@
-# This Makefile.am is in the public domain
-all:
- @echo -e \
-"Generate documentation:\n" \
-"\tmake full - full documentation with dependency graphs (slow)\n" \
-"\tmake fast - fast mode without dependency graphs"
-
-full: sync.doxy
- doxygen $<
-
-fast: sync.doxy
- sed 's/\(HAVE_DOT.*=\).*/\1 NO/' $< | doxygen -
-
-clean:
- rm -rf html
-
-EXTRA_DIST = \
- sync.doxy
diff --git a/m4/ax_compare_version.m4 b/m4/ax_compare_version.m4
@@ -1,177 +0,0 @@
-# ===========================================================================
-# https://www.gnu.org/software/autoconf-archive/ax_compare_version.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-# AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
-#
-# DESCRIPTION
-#
-# This macro compares two version strings. Due to the various number of
-# minor-version numbers that can exist, and the fact that string
-# comparisons are not compatible with numeric comparisons, this is not
-# necessarily trivial to do in a autoconf script. This macro makes doing
-# these comparisons easy.
-#
-# The six basic comparisons are available, as well as checking equality
-# limited to a certain number of minor-version levels.
-#
-# The operator OP determines what type of comparison to do, and can be one
-# of:
-#
-# eq - equal (test A == B)
-# ne - not equal (test A != B)
-# le - less than or equal (test A <= B)
-# ge - greater than or equal (test A >= B)
-# lt - less than (test A < B)
-# gt - greater than (test A > B)
-#
-# Additionally, the eq and ne operator can have a number after it to limit
-# the test to that number of minor versions.
-#
-# eq0 - equal up to the length of the shorter version
-# ne0 - not equal up to the length of the shorter version
-# eqN - equal up to N sub-version levels
-# neN - not equal up to N sub-version levels
-#
-# When the condition is true, shell commands ACTION-IF-TRUE are run,
-# otherwise shell commands ACTION-IF-FALSE are run. The environment
-# variable 'ax_compare_version' is always set to either 'true' or 'false'
-# as well.
-#
-# Examples:
-#
-# AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
-# AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
-#
-# would both be true.
-#
-# AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
-# AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
-#
-# would both be false.
-#
-# AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
-#
-# would be true because it is only comparing two minor versions.
-#
-# AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
-#
-# would be true because it is only comparing the lesser number of minor
-# versions of the two values.
-#
-# Note: The characters that separate the version numbers do not matter. An
-# empty string is the same as version 0. OP is evaluated by autoconf, not
-# configure, so must be a string, not a variable.
-#
-# The author would like to acknowledge Guido Draheim whose advice about
-# the m4_case and m4_ifvaln functions make this macro only include the
-# portions necessary to perform the specific comparison specified by the
-# OP argument in the final configure script.
-#
-# LICENSE
-#
-# Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu>
-#
-# Copying and distribution of this file, with or without modification, are
-# permitted in any medium without royalty provided the copyright notice
-# and this notice are preserved. This file is offered as-is, without any
-# warranty.
-
-#serial 13
-
-dnl #########################################################################
-AC_DEFUN([AX_COMPARE_VERSION], [
- AC_REQUIRE([AC_PROG_AWK])
-
- # Used to indicate true or false condition
- ax_compare_version=false
-
- # Convert the two version strings to be compared into a format that
- # allows a simple string comparison. The end result is that a version
- # string of the form 1.12.5-r617 will be converted to the form
- # 0001001200050617. In other words, each number is zero padded to four
- # digits, and non digits are removed.
- AS_VAR_PUSHDEF([A],[ax_compare_version_A])
- A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
- -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
- -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
- -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
- -e 's/[[^0-9]]//g'`
-
- AS_VAR_PUSHDEF([B],[ax_compare_version_B])
- B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
- -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
- -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
- -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
- -e 's/[[^0-9]]//g'`
-
- dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
- dnl # then the first line is used to determine if the condition is true.
- dnl # The sed right after the echo is to remove any indented white space.
- m4_case(m4_tolower($2),
- [lt],[
- ax_compare_version=`echo "x$A
-x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
- ],
- [gt],[
- ax_compare_version=`echo "x$A
-x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
- ],
- [le],[
- ax_compare_version=`echo "x$A
-x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
- ],
- [ge],[
- ax_compare_version=`echo "x$A
-x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
- ],[
- dnl Split the operator from the subversion count if present.
- m4_bmatch(m4_substr($2,2),
- [0],[
- # A count of zero means use the length of the shorter version.
- # Determine the number of characters in A and B.
- ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
- ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
-
- # Set A to no more than B's length and B to no more than A's length.
- A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
- B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
- ],
- [[0-9]+],[
- # A count greater than zero means use only that many subversions
- A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
- B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
- ],
- [.+],[
- AC_WARNING(
- [invalid OP numeric parameter: $2])
- ],[])
-
- # Pad zeros at end of numbers to make same length.
- ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
- B="$B`echo $A | sed 's/./0/g'`"
- A="$ax_compare_version_tmp_A"
-
- # Check for equality or inequality as necessary.
- m4_case(m4_tolower(m4_substr($2,0,2)),
- [eq],[
- test "x$A" = "x$B" && ax_compare_version=true
- ],
- [ne],[
- test "x$A" != "x$B" && ax_compare_version=true
- ],[
- AC_WARNING([invalid OP parameter: $2])
- ])
- ])
-
- AS_VAR_POPDEF([A])dnl
- AS_VAR_POPDEF([B])dnl
-
- dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
- if test "$ax_compare_version" = "true" ; then
- m4_ifvaln([$4],[$4],[:])dnl
- m4_ifvaln([$5],[else $5])dnl
- fi
-]) dnl AX_COMPARE_VERSION
diff --git a/m4/ax_lib_postgresql.m4 b/m4/ax_lib_postgresql.m4
@@ -1,247 +0,0 @@
-# ===========================================================================
-# https://www.gnu.org/software/autoconf-archive/ax_lib_postgresql.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-# AX_LIB_POSTGRESQL([MINIMUM-VERSION],[ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
-#
-# DESCRIPTION
-#
-# This macro provides tests of availability of PostgreSQL 'libpq' library
-# of particular version or newer.
-#
-# AX_LIB_POSTGRESQL macro takes only one argument which is optional. If
-# there is no required version passed, then macro does not run version
-# test.
-#
-# The --with-postgresql option takes one of three possible values:
-#
-# no - do not check for PostgreSQL client library
-#
-# yes - do check for PostgreSQL library in standard locations (pg_config
-# should be in the PATH)
-#
-# path - complete path to pg_config utility, use this option if pg_config
-# can't be found in the PATH (You could set also PG_CONFIG variable)
-#
-# This macro calls:
-#
-# AC_SUBST(POSTGRESQL_CPPFLAGS)
-# AC_SUBST(POSTGRESQL_LDFLAGS)
-# AC_SUBST(POSTGRESQL_LIBS)
-# AC_SUBST(POSTGRESQL_VERSION)
-#
-# And sets:
-#
-# HAVE_POSTGRESQL
-#
-# It execute if found ACTION-IF-FOUND (empty by default) and
-# ACTION-IF-NOT-FOUND (AC_MSG_FAILURE by default) if not found.
-#
-# LICENSE
-#
-# Copyright (c) 2008 Mateusz Loskot <mateusz@loskot.net>
-# Copyright (c) 2014 Sree Harsha Totakura <sreeharsha@totakura.in>
-# Copyright (c) 2018 Bastien Roucaries <rouca@debian.org>
-#
-# Copying and distribution of this file, with or without modification, are
-# permitted in any medium without royalty provided the copyright notice
-# and this notice are preserved. This file is offered as-is, without any
-# warranty.
-
-#serial 22
-
-AC_DEFUN([_AX_LIB_POSTGRESQL_OLD],[
- found_postgresql="no"
- _AX_LIB_POSTGRESQL_OLD_fail="no"
- while true; do
- AC_CACHE_CHECK([for the pg_config program], [ac_cv_path_PG_CONFIG],
- [AC_PATH_PROGS_FEATURE_CHECK([PG_CONFIG], [pg_config],
- [[ac_cv_path_PG_CONFIG="";$ac_path_PG_CONFIG --includedir > /dev/null \
- && ac_cv_path_PG_CONFIG=$ac_path_PG_CONFIG ac_path_PG_CONFIG_found=:]],
- [ac_cv_path_PG_CONFIG=""])])
- PG_CONFIG=$ac_cv_path_PG_CONFIG
- AS_IF([test "X$PG_CONFIG" = "X"],[break])
-
- AC_CACHE_CHECK([for the PostgreSQL libraries CPPFLAGS],[ac_cv_POSTGRESQL_CPPFLAGS],
- [ac_cv_POSTGRESQL_CPPFLAGS="-I`$PG_CONFIG --includedir`" || _AX_LIB_POSTGRESQL_OLD_fail=yes])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_OLD_fail" = "Xyes"],[break])
- POSTGRESQL_CPPFLAGS="$ac_cv_POSTGRESQL_CPPFLAGS"
-
- AC_CACHE_CHECK([for the PostgreSQL libraries LDFLAGS],[ac_cv_POSTGRESQL_LDFLAGS],
- [ac_cv_POSTGRESQL_LDFLAGS="-L`$PG_CONFIG --libdir`" || _AX_LIB_POSTGRESQL_OLD_fail=yes])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_OLD_fail" = "Xyes"],[break])
- POSTGRESQL_LDFLAGS="$ac_cv_POSTGRESQL_LDFLAGS"
-
- AC_CACHE_CHECK([for the PostgreSQL libraries LIBS],[ac_cv_POSTGRESQL_LIBS],
- [ac_cv_POSTGRESQL_LIBS="-lpq"])
- POSTGRESQL_LIBS="$ac_cv_POSTGRESQL_LIBS"
-
- AC_CACHE_CHECK([for the PostgreSQL version],[ac_cv_POSTGRESQL_VERSION],
- [
- ac_cv_POSTGRESQL_VERSION=`$PG_CONFIG --version | sed "s/^PostgreSQL[[[:space:]]][[[:space:]]]*\([[0-9.]][[0-9.]]*\).*/\1/"` \
- || _AX_LIB_POSTGRESQL_OLD_fail=yes
- ])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_OLD_fail" = "Xyes"],[break])
- POSTGRESQL_VERSION="$ac_cv_POSTGRESQL_VERSION"
-
-
- dnl
- dnl Check if required version of PostgreSQL is available
- dnl
- AS_IF([test X"$postgresql_version_req" != "X"],[
- AC_MSG_CHECKING([if PostgreSQL version $POSTGRESQL_VERSION is >= $postgresql_version_req])
- AX_COMPARE_VERSION([$POSTGRESQL_VERSION],[ge],[$postgresql_version_req],
- [found_postgresql_req_version=yes],[found_postgresql_req_version=no])
- AC_MSG_RESULT([$found_postgresql_req_version])
- ])
- AS_IF([test "Xfound_postgresql_req_version" = "Xno"],[break])
-
- found_postgresql="yes"
- break
- done
-])
-
-AC_DEFUN([_AX_LIB_POSTGRESQL_PKG_CONFIG],
-[
- AC_REQUIRE([PKG_PROG_PKG_CONFIG])
- found_postgresql=no
-
- while true; do
- PKG_PROG_PKG_CONFIG
- AS_IF([test X$PKG_CONFIG = X],[break])
-
- _AX_LIB_POSTGRESQL_PKG_CONFIG_fail=no;
- AS_IF([test "X$postgresql_version_req" = "X"],
- [PKG_CHECK_EXISTS([libpq],[found_postgresql_pkg_config=yes],[found_postgresql=no])],
- [PKG_CHECK_EXISTS([libpq >= "$postgresql_version_req"],
- [found_postgresql=yes],[found_postgresql=no])])
- AS_IF([test "X$found_postgresql" = "no"],[break])
-
- AC_CACHE_CHECK([for the PostgreSQL libraries CPPFLAGS],[ac_cv_POSTGRESQL_CPPFLAGS],
- [ac_cv_POSTGRESQL_CPPFLAGS="`$PKG_CONFIG libpq --cflags-only-I`" || _AX_LIB_POSTGRESQL_PKG_CONFIG_fail=yes])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_PKG_CONFIG_fail" = "Xyes"],[break])
- POSTGRESQL_CPPFLAGS="$ac_cv_POSTGRESQL_CPPFLAGS"
-
-
- AC_CACHE_CHECK([for the PostgreSQL libraries LDFLAGS],[ac_cv_POSTGRESQL_LDFLAGS],
- [ac_cv_POSTGRESQL_LDFLAGS="`$PKG_CONFIG libpq --libs-only-L --libs-only-other`" || _AX_LIB_POSTGRESQL_PKG_CONFIG_fail=yes])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_PKG_CONFIG_fail" = "Xyes"],[break])
- POSTGRESQL_LDFLAGS="$ac_cv_POSTGRESQL_LDFLAGS"
-
-
- AC_CACHE_CHECK([for the PostgreSQL libraries LIBS],[ac_cv_POSTGRESQL_LIBS],
- [ac_cv_POSTGRESQL_LIBS="`$PKG_CONFIG libpq --libs-only-l`" || _AX_LIB_POSTGRESQL_PKG_CONFIG_fail=ye])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_PKG_CONFIG_fail" = "Xyes"],[break])
- POSTGRESQL_LIBS="$ac_cv_POSTGRESQL_LIBS"
-
- dnl already checked by exist but need to be recovered
- AC_CACHE_CHECK([for the PostgreSQL version],[ac_cv_POSTGRESQL_VERSION],
- [ac_cv_POSTGRESQL_VERSION="`$PKG_CONFIG libpq --modversion`" || _AX_LIB_POSTGRESQL_PKG_CONFIG_fail=yes])
- AS_IF([test "X$_AX_LIB_POSTGRESQL_PKG_CONFIG_fail" = "Xyes"],[break])
- POSTGRESQL_VERSION="$ac_cv_POSTGRESQL_VERSION"
-
- found_postgresql=yes
- break;
- done
-
-])
-
-
-
-AC_DEFUN([AX_LIB_POSTGRESQL],
-[
- AC_ARG_WITH([postgresql],
- AS_HELP_STRING([--with-postgresql=@<:@ARG@:>@],
- [use PostgreSQL library @<:@default=yes@:>@, optionally specify path to pg_config]
- ),
- [
- AS_CASE([$withval],
- [[[nN]][[oO]]],[want_postgresql="no"],
- [[[yY]][[eE]][[sS]]],[want_postgresql="yes"],
- [
- want_postgresql="yes"
- PG_CONFIG="$withval"
- ])
- ],
- [want_postgresql="yes"]
- )
-
- AC_ARG_VAR([POSTGRESQL_CPPFLAGS],[cpp flags for PostgreSQL overriding detected flags])
- AC_ARG_VAR([POSTGRESQL_LIBFLAGS],[libs for PostgreSQL overriding detected flags])
- AC_ARG_VAR([POSTGRESQL_LDFLAGS],[linker flags for PostgreSQL overriding detected flags])
-
- # populate cache
- AS_IF([test "X$POSTGRESQL_CPPFLAGS" != X],[ac_cv_POSTGRESQL_CPPFLAGS="$POSTGRESQL_CPPFLAGS"])
- AS_IF([test "X$POSTGRESQL_LDFLAGS" != X],[ac_cv_POSTGRESQL_LDFLAGS="$POSTGRESQL_LDFLAGS"])
- AS_IF([test "X$POSTGRESQL_LIBS" != X],[ac_cv_POSTGRESQL_LIBS="$POSTGRESQL_LIBS"])
-
- postgresql_version_req=ifelse([$1], [], [], [$1])
- found_postgresql="no"
-
- POSTGRESQL_VERSION=""
-
- dnl
- dnl Check PostgreSQL libraries (libpq)
- dnl
- AS_IF([test X"$want_postgresql" = "Xyes"],[
- _AX_LIB_POSTGRESQL_PKG_CONFIG
-
-
- AS_IF([test X"$found_postgresql" = "Xno"],
- [_AX_LIB_POSTGRESQL_OLD])
-
- AS_IF([test X"$found_postgresql" = Xyes],[
- _AX_LIB_POSTGRESQL_OLD_CPPFLAGS="$CPPFLAGS"
- CPPFLAGS="$CPPFLAGS $POSTGRESQL_CPPFLAGS"
- _AX_LIB_POSTGRESQL_OLD_LDFLAGS="$LDFLAGS"
- LDFLAGS="$LDFLAGS $POSTGRESQL_LDFLAGS"
- _AX_LIB_POSTGRESQL_OLD_LIBS="$LIBS"
- LIBS="$LIBS $POSTGRESQL_LIBS"
- while true; do
- dnl try to compile
- AC_CHECK_HEADER([libpq-fe.h],[],[found_postgresql=no])
- AS_IF([test "X$found_postgresql" = "Xno"],[break])
- dnl try now to link
- AC_CACHE_CHECK([for the PostgreSQL library linking is working],[ac_cv_postgresql_found],
- [
- AC_LINK_IFELSE([
- AC_LANG_PROGRAM(
- [
- #include <libpq-fe.h>
- ],
- [[
- char conninfo[]="dbname = postgres";
- PGconn *conn;
- conn = PQconnectdb(conninfo);
- ]]
- )
- ],[ac_cv_postgresql_found=yes],
- [ac_cv_postgresql_found=no])
- ])
- found_postgresql="$ac_cv_postgresql_found"
- AS_IF([test "X$found_postgresql" = "Xno"],[break])
- break
- done
- CPPFLAGS="$_AX_LIB_POSTGRESQL_OLD_CPPFLAGS"
- LDFLAGS="$_AX_LIB_POSTGRESQL_OLD_LDFLAGS"
- LIBS="$_AX_LIB_POSTGRESQL_OLD_LIBS"
- ])
-
-
- AS_IF([test "x$found_postgresql" = "xyes"],[
- AC_DEFINE([HAVE_POSTGRESQL], [1],
- [Define to 1 if PostgreSQL libraries are available])])
- ])
-
- AC_SUBST([POSTGRESQL_VERSION])
- AC_SUBST([POSTGRESQL_CPPFLAGS])
- AC_SUBST([POSTGRESQL_LDFLAGS])
- AC_SUBST([POSTGRESQL_LIBS])
-
- AS_IF([test "x$found_postgresql" = "xyes"],
- [ifelse([$2], , :, [$2])],
- [ifelse([$3], , AS_IF([test X"$want_postgresql" = "Xyes"],[AC_MSG_ERROR([Library requirements (PostgreSQL) not met.])],[:]), [$3])])
-
-])
diff --git a/m4/ax_prog_doxygen.m4 b/m4/ax_prog_doxygen.m4
@@ -1,586 +0,0 @@
-# ===========================================================================
-# https://www.gnu.org/software/autoconf-archive/ax_prog_doxygen.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-# DX_INIT_DOXYGEN(PROJECT-NAME, [DOXYFILE-PATH], [OUTPUT-DIR], ...)
-# DX_DOXYGEN_FEATURE(ON|OFF)
-# DX_DOT_FEATURE(ON|OFF)
-# DX_HTML_FEATURE(ON|OFF)
-# DX_CHM_FEATURE(ON|OFF)
-# DX_CHI_FEATURE(ON|OFF)
-# DX_MAN_FEATURE(ON|OFF)
-# DX_RTF_FEATURE(ON|OFF)
-# DX_XML_FEATURE(ON|OFF)
-# DX_PDF_FEATURE(ON|OFF)
-# DX_PS_FEATURE(ON|OFF)
-#
-# DESCRIPTION
-#
-# The DX_*_FEATURE macros control the default setting for the given
-# Doxygen feature. Supported features are 'DOXYGEN' itself, 'DOT' for
-# generating graphics, 'HTML' for plain HTML, 'CHM' for compressed HTML
-# help (for MS users), 'CHI' for generating a separate .chi file by the
-# .chm file, and 'MAN', 'RTF', 'XML', 'PDF' and 'PS' for the appropriate
-# output formats. The environment variable DOXYGEN_PAPER_SIZE may be
-# specified to override the default 'a4wide' paper size.
-#
-# By default, HTML, PDF and PS documentation is generated as this seems to
-# be the most popular and portable combination. MAN pages created by
-# Doxygen are usually problematic, though by picking an appropriate subset
-# and doing some massaging they might be better than nothing. CHM and RTF
-# are specific for MS (note that you can't generate both HTML and CHM at
-# the same time). The XML is rather useless unless you apply specialized
-# post-processing to it.
-#
-# The macros mainly control the default state of the feature. The use can
-# override the default by specifying --enable or --disable. The macros
-# ensure that contradictory flags are not given (e.g.,
-# --enable-doxygen-html and --enable-doxygen-chm,
-# --enable-doxygen-anything with --disable-doxygen, etc.) Finally, each
-# feature will be automatically disabled (with a warning) if the required
-# programs are missing.
-#
-# Once all the feature defaults have been specified, call DX_INIT_DOXYGEN
-# with the following parameters: a one-word name for the project for use
-# as a filename base etc., an optional configuration file name (the
-# default is '$(srcdir)/Doxyfile', the same as Doxygen's default), and an
-# optional output directory name (the default is 'doxygen-doc'). To run
-# doxygen multiple times for different configuration files and output
-# directories provide more parameters: the second, forth, sixth, etc
-# parameter are configuration file names and the third, fifth, seventh,
-# etc parameter are output directories. No checking is done to catch
-# duplicates.
-#
-# Automake Support
-#
-# The DX_RULES substitution can be used to add all needed rules to the
-# Makefile. Note that this is a substitution without being a variable:
-# only the @DX_RULES@ syntax will work.
-#
-# The provided targets are:
-#
-# doxygen-doc: Generate all doxygen documentation.
-#
-# doxygen-run: Run doxygen, which will generate some of the
-# documentation (HTML, CHM, CHI, MAN, RTF, XML)
-# but will not do the post processing required
-# for the rest of it (PS, PDF).
-#
-# doxygen-ps: Generate doxygen PostScript documentation.
-#
-# doxygen-pdf: Generate doxygen PDF documentation.
-#
-# Note that by default these are not integrated into the automake targets.
-# If doxygen is used to generate man pages, you can achieve this
-# integration by setting man3_MANS to the list of man pages generated and
-# then adding the dependency:
-#
-# $(man3_MANS): doxygen-doc
-#
-# This will cause make to run doxygen and generate all the documentation.
-#
-# The following variable is intended for use in Makefile.am:
-#
-# DX_CLEANFILES = everything to clean.
-#
-# Then add this variable to MOSTLYCLEANFILES.
-#
-# LICENSE
-#
-# Copyright (c) 2009 Oren Ben-Kiki <oren@ben-kiki.org>
-# Copyright (c) 2015 Olaf Mandel <olaf@mandel.name>
-#
-# Copying and distribution of this file, with or without modification, are
-# permitted in any medium without royalty provided the copyright notice
-# and this notice are preserved. This file is offered as-is, without any
-# warranty.
-
-#serial 23
-
-## ----------##
-## Defaults. ##
-## ----------##
-
-DX_ENV=""
-AC_DEFUN([DX_FEATURE_doc], ON)
-AC_DEFUN([DX_FEATURE_dot], OFF)
-AC_DEFUN([DX_FEATURE_man], OFF)
-AC_DEFUN([DX_FEATURE_html], ON)
-AC_DEFUN([DX_FEATURE_chm], OFF)
-AC_DEFUN([DX_FEATURE_chi], OFF)
-AC_DEFUN([DX_FEATURE_rtf], OFF)
-AC_DEFUN([DX_FEATURE_xml], OFF)
-AC_DEFUN([DX_FEATURE_pdf], ON)
-AC_DEFUN([DX_FEATURE_ps], ON)
-
-## --------------- ##
-## Private macros. ##
-## --------------- ##
-
-# DX_ENV_APPEND(VARIABLE, VALUE)
-# ------------------------------
-# Append VARIABLE="VALUE" to DX_ENV for invoking doxygen and add it
-# as a substitution (but not a Makefile variable). The substitution
-# is skipped if the variable name is VERSION.
-AC_DEFUN([DX_ENV_APPEND],
-[AC_SUBST([DX_ENV], ["$DX_ENV $1='$2'"])dnl
-m4_if([$1], [VERSION], [], [AC_SUBST([$1], [$2])dnl
-AM_SUBST_NOTMAKE([$1])])dnl
-])
-
-# DX_DIRNAME_EXPR
-# ---------------
-# Expand into a shell expression prints the directory part of a path.
-AC_DEFUN([DX_DIRNAME_EXPR],
- [[expr ".$1" : '\(\.\)[^/]*$' \| "x$1" : 'x\(.*\)/[^/]*$']])
-
-# DX_IF_FEATURE(FEATURE, IF-ON, IF-OFF)
-# -------------------------------------
-# Expands according to the M4 (static) status of the feature.
-AC_DEFUN([DX_IF_FEATURE], [ifelse(DX_FEATURE_$1, ON, [$2], [$3])])
-
-# DX_REQUIRE_PROG(VARIABLE, PROGRAM)
-# ----------------------------------
-# Require the specified program to be found for the DX_CURRENT_FEATURE to work.
-AC_DEFUN([DX_REQUIRE_PROG], [
-AC_PATH_TOOL([$1], [$2])
-if test "$DX_FLAG_[]DX_CURRENT_FEATURE$$1" = 1; then
- AC_MSG_WARN([$2 not found - will not DX_CURRENT_DESCRIPTION])
- AC_SUBST(DX_FLAG_[]DX_CURRENT_FEATURE, 0)
-fi
-])
-
-# DX_TEST_FEATURE(FEATURE)
-# ------------------------
-# Expand to a shell expression testing whether the feature is active.
-AC_DEFUN([DX_TEST_FEATURE], [test "$DX_FLAG_$1" = 1])
-
-# DX_CHECK_DEPEND(REQUIRED_FEATURE, REQUIRED_STATE)
-# -------------------------------------------------
-# Verify that a required features has the right state before trying to turn on
-# the DX_CURRENT_FEATURE.
-AC_DEFUN([DX_CHECK_DEPEND], [
-test "$DX_FLAG_$1" = "$2" \
-|| AC_MSG_ERROR([doxygen-DX_CURRENT_FEATURE ifelse([$2], 1,
- requires, contradicts) doxygen-DX_CURRENT_FEATURE])
-])
-
-# DX_CLEAR_DEPEND(FEATURE, REQUIRED_FEATURE, REQUIRED_STATE)
-# ----------------------------------------------------------
-# Turn off the DX_CURRENT_FEATURE if the required feature is off.
-AC_DEFUN([DX_CLEAR_DEPEND], [
-test "$DX_FLAG_$1" = "$2" || AC_SUBST(DX_FLAG_[]DX_CURRENT_FEATURE, 0)
-])
-
-# DX_FEATURE_ARG(FEATURE, DESCRIPTION,
-# CHECK_DEPEND, CLEAR_DEPEND,
-# REQUIRE, DO-IF-ON, DO-IF-OFF)
-# --------------------------------------------
-# Parse the command-line option controlling a feature. CHECK_DEPEND is called
-# if the user explicitly turns the feature on (and invokes DX_CHECK_DEPEND),
-# otherwise CLEAR_DEPEND is called to turn off the default state if a required
-# feature is disabled (using DX_CLEAR_DEPEND). REQUIRE performs additional
-# requirement tests (DX_REQUIRE_PROG). Finally, an automake flag is set and
-# DO-IF-ON or DO-IF-OFF are called according to the final state of the feature.
-AC_DEFUN([DX_ARG_ABLE], [
- AC_DEFUN([DX_CURRENT_FEATURE], [$1])
- AC_DEFUN([DX_CURRENT_DESCRIPTION], [$2])
- AC_ARG_ENABLE(doxygen-$1,
- [AS_HELP_STRING(DX_IF_FEATURE([$1], [--disable-doxygen-$1],
- [--enable-doxygen-$1]),
- DX_IF_FEATURE([$1], [don't $2], [$2]))],
- [
-case "$enableval" in
-#(
-y|Y|yes|Yes|YES)
- AC_SUBST([DX_FLAG_$1], 1)
- $3
-;; #(
-n|N|no|No|NO)
- AC_SUBST([DX_FLAG_$1], 0)
-;; #(
-*)
- AC_MSG_ERROR([invalid value '$enableval' given to doxygen-$1])
-;;
-esac
-], [
-AC_SUBST([DX_FLAG_$1], [DX_IF_FEATURE([$1], 1, 0)])
-$4
-])
-if DX_TEST_FEATURE([$1]); then
- $5
- :
-fi
-if DX_TEST_FEATURE([$1]); then
- $6
- :
-else
- $7
- :
-fi
-])
-
-## -------------- ##
-## Public macros. ##
-## -------------- ##
-
-# DX_XXX_FEATURE(DEFAULT_STATE)
-# -----------------------------
-AC_DEFUN([DX_DOXYGEN_FEATURE], [AC_DEFUN([DX_FEATURE_doc], [$1])])
-AC_DEFUN([DX_DOT_FEATURE], [AC_DEFUN([DX_FEATURE_dot], [$1])])
-AC_DEFUN([DX_MAN_FEATURE], [AC_DEFUN([DX_FEATURE_man], [$1])])
-AC_DEFUN([DX_HTML_FEATURE], [AC_DEFUN([DX_FEATURE_html], [$1])])
-AC_DEFUN([DX_CHM_FEATURE], [AC_DEFUN([DX_FEATURE_chm], [$1])])
-AC_DEFUN([DX_CHI_FEATURE], [AC_DEFUN([DX_FEATURE_chi], [$1])])
-AC_DEFUN([DX_RTF_FEATURE], [AC_DEFUN([DX_FEATURE_rtf], [$1])])
-AC_DEFUN([DX_XML_FEATURE], [AC_DEFUN([DX_FEATURE_xml], [$1])])
-AC_DEFUN([DX_XML_FEATURE], [AC_DEFUN([DX_FEATURE_xml], [$1])])
-AC_DEFUN([DX_PDF_FEATURE], [AC_DEFUN([DX_FEATURE_pdf], [$1])])
-AC_DEFUN([DX_PS_FEATURE], [AC_DEFUN([DX_FEATURE_ps], [$1])])
-
-# DX_INIT_DOXYGEN(PROJECT, [CONFIG-FILE], [OUTPUT-DOC-DIR], ...)
-# --------------------------------------------------------------
-# PROJECT also serves as the base name for the documentation files.
-# The default CONFIG-FILE is "$(srcdir)/Doxyfile" and OUTPUT-DOC-DIR is
-# "doxygen-doc".
-# More arguments are interpreted as interleaved CONFIG-FILE and
-# OUTPUT-DOC-DIR values.
-AC_DEFUN([DX_INIT_DOXYGEN], [
-
-# Files:
-AC_SUBST([DX_PROJECT], [$1])
-AC_SUBST([DX_CONFIG], ['ifelse([$2], [], [$(srcdir)/Doxyfile], [$2])'])
-AC_SUBST([DX_DOCDIR], ['ifelse([$3], [], [doxygen-doc], [$3])'])
-m4_if(m4_eval(3 < m4_count($@)), 1, [m4_for([DX_i], 4, m4_count($@), 2,
- [AC_SUBST([DX_CONFIG]m4_eval(DX_i[/2]),
- 'm4_default_nblank_quoted(m4_argn(DX_i, $@),
- [$(srcdir)/Doxyfile])')])])dnl
-m4_if(m4_eval(3 < m4_count($@)), 1, [m4_for([DX_i], 5, m4_count($@,), 2,
- [AC_SUBST([DX_DOCDIR]m4_eval([(]DX_i[-1)/2]),
- 'm4_default_nblank_quoted(m4_argn(DX_i, $@),
- [doxygen-doc])')])])dnl
-m4_define([DX_loop], m4_dquote(m4_if(m4_eval(3 < m4_count($@)), 1,
- [m4_for([DX_i], 4, m4_count($@), 2, [, m4_eval(DX_i[/2])])],
- [])))dnl
-
-# Environment variables used inside doxygen.cfg:
-DX_ENV_APPEND(SRCDIR, $srcdir)
-DX_ENV_APPEND(PROJECT, $DX_PROJECT)
-DX_ENV_APPEND(VERSION, $PACKAGE_VERSION)
-
-# Doxygen itself:
-DX_ARG_ABLE(doc, [generate any doxygen documentation],
- [],
- [],
- [DX_REQUIRE_PROG([DX_DOXYGEN], doxygen)
- DX_REQUIRE_PROG([DX_PERL], perl)],
- [DX_ENV_APPEND(PERL_PATH, $DX_PERL)])
-
-# Dot for graphics:
-DX_ARG_ABLE(dot, [generate graphics for doxygen documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [DX_REQUIRE_PROG([DX_DOT], dot)],
- [DX_ENV_APPEND(HAVE_DOT, YES)
- DX_ENV_APPEND(DOT_PATH, [`DX_DIRNAME_EXPR($DX_DOT)`])],
- [DX_ENV_APPEND(HAVE_DOT, NO)])
-
-# Man pages generation:
-DX_ARG_ABLE(man, [generate doxygen manual pages],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [],
- [DX_ENV_APPEND(GENERATE_MAN, YES)],
- [DX_ENV_APPEND(GENERATE_MAN, NO)])
-
-# RTF file generation:
-DX_ARG_ABLE(rtf, [generate doxygen RTF documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [],
- [DX_ENV_APPEND(GENERATE_RTF, YES)],
- [DX_ENV_APPEND(GENERATE_RTF, NO)])
-
-# XML file generation:
-DX_ARG_ABLE(xml, [generate doxygen XML documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [],
- [DX_ENV_APPEND(GENERATE_XML, YES)],
- [DX_ENV_APPEND(GENERATE_XML, NO)])
-
-# (Compressed) HTML help generation:
-DX_ARG_ABLE(chm, [generate doxygen compressed HTML help documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [DX_REQUIRE_PROG([DX_HHC], hhc)],
- [DX_ENV_APPEND(HHC_PATH, $DX_HHC)
- DX_ENV_APPEND(GENERATE_HTML, YES)
- DX_ENV_APPEND(GENERATE_HTMLHELP, YES)],
- [DX_ENV_APPEND(GENERATE_HTMLHELP, NO)])
-
-# Separate CHI file generation.
-DX_ARG_ABLE(chi, [generate doxygen separate compressed HTML help index file],
- [DX_CHECK_DEPEND(chm, 1)],
- [DX_CLEAR_DEPEND(chm, 1)],
- [],
- [DX_ENV_APPEND(GENERATE_CHI, YES)],
- [DX_ENV_APPEND(GENERATE_CHI, NO)])
-
-# Plain HTML pages generation:
-DX_ARG_ABLE(html, [generate doxygen plain HTML documentation],
- [DX_CHECK_DEPEND(doc, 1) DX_CHECK_DEPEND(chm, 0)],
- [DX_CLEAR_DEPEND(doc, 1) DX_CLEAR_DEPEND(chm, 0)],
- [],
- [DX_ENV_APPEND(GENERATE_HTML, YES)],
- [DX_TEST_FEATURE(chm) || DX_ENV_APPEND(GENERATE_HTML, NO)])
-
-# PostScript file generation:
-DX_ARG_ABLE(ps, [generate doxygen PostScript documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [DX_REQUIRE_PROG([DX_LATEX], latex)
- DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
- DX_REQUIRE_PROG([DX_DVIPS], dvips)
- DX_REQUIRE_PROG([DX_EGREP], egrep)])
-
-# PDF file generation:
-DX_ARG_ABLE(pdf, [generate doxygen PDF documentation],
- [DX_CHECK_DEPEND(doc, 1)],
- [DX_CLEAR_DEPEND(doc, 1)],
- [DX_REQUIRE_PROG([DX_PDFLATEX], pdflatex)
- DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
- DX_REQUIRE_PROG([DX_EGREP], egrep)])
-
-# LaTeX generation for PS and/or PDF:
-if DX_TEST_FEATURE(ps) || DX_TEST_FEATURE(pdf); then
- DX_ENV_APPEND(GENERATE_LATEX, YES)
-else
- DX_ENV_APPEND(GENERATE_LATEX, NO)
-fi
-
-# Paper size for PS and/or PDF:
-AC_ARG_VAR(DOXYGEN_PAPER_SIZE,
- [a4wide (default), a4, letter, legal or executive])
-case "$DOXYGEN_PAPER_SIZE" in
-#(
-"")
- AC_SUBST(DOXYGEN_PAPER_SIZE, "")
-;; #(
-a4wide|a4|letter|legal|executive)
- DX_ENV_APPEND(PAPER_SIZE, $DOXYGEN_PAPER_SIZE)
-;; #(
-*)
- AC_MSG_ERROR([unknown DOXYGEN_PAPER_SIZE='$DOXYGEN_PAPER_SIZE'])
-;;
-esac
-
-# Rules:
-AS_IF([[test $DX_FLAG_html -eq 1]],
-[[DX_SNIPPET_html="## ------------------------------- ##
-## Rules specific for HTML output. ##
-## ------------------------------- ##
-
-DX_CLEAN_HTML = \$(DX_DOCDIR)/html]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/html]])[
-
-"]],
-[[DX_SNIPPET_html=""]])
-AS_IF([[test $DX_FLAG_chi -eq 1]],
-[[DX_SNIPPET_chi="
-DX_CLEAN_CHI = \$(DX_DOCDIR)/\$(PACKAGE).chi]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).chi]])["]],
-[[DX_SNIPPET_chi=""]])
-AS_IF([[test $DX_FLAG_chm -eq 1]],
-[[DX_SNIPPET_chm="## ------------------------------ ##
-## Rules specific for CHM output. ##
-## ------------------------------ ##
-
-DX_CLEAN_CHM = \$(DX_DOCDIR)/chm]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/chm]])[\
-${DX_SNIPPET_chi}
-
-"]],
-[[DX_SNIPPET_chm=""]])
-AS_IF([[test $DX_FLAG_man -eq 1]],
-[[DX_SNIPPET_man="## ------------------------------ ##
-## Rules specific for MAN output. ##
-## ------------------------------ ##
-
-DX_CLEAN_MAN = \$(DX_DOCDIR)/man]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/man]])[
-
-"]],
-[[DX_SNIPPET_man=""]])
-AS_IF([[test $DX_FLAG_rtf -eq 1]],
-[[DX_SNIPPET_rtf="## ------------------------------ ##
-## Rules specific for RTF output. ##
-## ------------------------------ ##
-
-DX_CLEAN_RTF = \$(DX_DOCDIR)/rtf]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/rtf]])[
-
-"]],
-[[DX_SNIPPET_rtf=""]])
-AS_IF([[test $DX_FLAG_xml -eq 1]],
-[[DX_SNIPPET_xml="## ------------------------------ ##
-## Rules specific for XML output. ##
-## ------------------------------ ##
-
-DX_CLEAN_XML = \$(DX_DOCDIR)/xml]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/xml]])[
-
-"]],
-[[DX_SNIPPET_xml=""]])
-AS_IF([[test $DX_FLAG_ps -eq 1]],
-[[DX_SNIPPET_ps="## ----------------------------- ##
-## Rules specific for PS output. ##
-## ----------------------------- ##
-
-DX_CLEAN_PS = \$(DX_DOCDIR)/\$(PACKAGE).ps]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).ps]])[
-
-DX_PS_GOAL = doxygen-ps
-
-doxygen-ps: \$(DX_CLEAN_PS)
-
-]m4_foreach([DX_i], [DX_loop],
-[[\$(DX_DOCDIR]DX_i[)/\$(PACKAGE).ps: \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).tag
- \$(DX_V_LATEX)cd \$(DX_DOCDIR]DX_i[)/latex; \\
- rm -f *.aux *.toc *.idx *.ind *.ilg *.log *.out; \\
- \$(DX_LATEX) refman.tex; \\
- \$(DX_MAKEINDEX) refman.idx; \\
- \$(DX_LATEX) refman.tex; \\
- countdown=5; \\
- while \$(DX_EGREP) 'Rerun (LaTeX|to get cross-references right)' \\
- refman.log > /dev/null 2>&1 \\
- && test \$\$countdown -gt 0; do \\
- \$(DX_LATEX) refman.tex; \\
- countdown=\`expr \$\$countdown - 1\`; \\
- done; \\
- \$(DX_DVIPS) -o ../\$(PACKAGE).ps refman.dvi
-
-]])["]],
-[[DX_SNIPPET_ps=""]])
-AS_IF([[test $DX_FLAG_pdf -eq 1]],
-[[DX_SNIPPET_pdf="## ------------------------------ ##
-## Rules specific for PDF output. ##
-## ------------------------------ ##
-
-DX_CLEAN_PDF = \$(DX_DOCDIR)/\$(PACKAGE).pdf]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).pdf]])[
-
-DX_PDF_GOAL = doxygen-pdf
-
-doxygen-pdf: \$(DX_CLEAN_PDF)
-
-]m4_foreach([DX_i], [DX_loop],
-[[\$(DX_DOCDIR]DX_i[)/\$(PACKAGE).pdf: \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).tag
- \$(DX_V_LATEX)cd \$(DX_DOCDIR]DX_i[)/latex; \\
- rm -f *.aux *.toc *.idx *.ind *.ilg *.log *.out; \\
- \$(DX_PDFLATEX) refman.tex; \\
- \$(DX_MAKEINDEX) refman.idx; \\
- \$(DX_PDFLATEX) refman.tex; \\
- countdown=5; \\
- while \$(DX_EGREP) 'Rerun (LaTeX|to get cross-references right)' \\
- refman.log > /dev/null 2>&1 \\
- && test \$\$countdown -gt 0; do \\
- \$(DX_PDFLATEX) refman.tex; \\
- countdown=\`expr \$\$countdown - 1\`; \\
- done; \\
- mv refman.pdf ../\$(PACKAGE).pdf
-
-]])["]],
-[[DX_SNIPPET_pdf=""]])
-AS_IF([[test $DX_FLAG_ps -eq 1 -o $DX_FLAG_pdf -eq 1]],
-[[DX_SNIPPET_latex="## ------------------------------------------------- ##
-## Rules specific for LaTeX (shared for PS and PDF). ##
-## ------------------------------------------------- ##
-
-DX_V_LATEX = \$(_DX_v_LATEX_\$(V))
-_DX_v_LATEX_ = \$(_DX_v_LATEX_\$(AM_DEFAULT_VERBOSITY))
-_DX_v_LATEX_0 = @echo \" LATEX \" \$][@;
-
-DX_CLEAN_LATEX = \$(DX_DOCDIR)/latex]dnl
-m4_foreach([DX_i], [m4_shift(DX_loop)], [[\\
- \$(DX_DOCDIR]DX_i[)/latex]])[
-
-"]],
-[[DX_SNIPPET_latex=""]])
-
-AS_IF([[test $DX_FLAG_doc -eq 1]],
-[[DX_SNIPPET_doc="## --------------------------------- ##
-## Format-independent Doxygen rules. ##
-## --------------------------------- ##
-
-${DX_SNIPPET_html}\
-${DX_SNIPPET_chm}\
-${DX_SNIPPET_man}\
-${DX_SNIPPET_rtf}\
-${DX_SNIPPET_xml}\
-${DX_SNIPPET_ps}\
-${DX_SNIPPET_pdf}\
-${DX_SNIPPET_latex}\
-DX_V_DXGEN = \$(_DX_v_DXGEN_\$(V))
-_DX_v_DXGEN_ = \$(_DX_v_DXGEN_\$(AM_DEFAULT_VERBOSITY))
-_DX_v_DXGEN_0 = @echo \" DXGEN \" \$<;
-
-.PHONY: doxygen-run doxygen-doc \$(DX_PS_GOAL) \$(DX_PDF_GOAL)
-
-.INTERMEDIATE: doxygen-run \$(DX_PS_GOAL) \$(DX_PDF_GOAL)
-
-doxygen-run:]m4_foreach([DX_i], [DX_loop],
- [[ \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).tag]])[
-
-doxygen-doc: doxygen-run \$(DX_PS_GOAL) \$(DX_PDF_GOAL)
-
-]m4_foreach([DX_i], [DX_loop],
-[[\$(DX_DOCDIR]DX_i[)/\$(PACKAGE).tag: \$(DX_CONFIG]DX_i[) \$(pkginclude_HEADERS)
- \$(A""M_V_at)rm -rf \$(DX_DOCDIR]DX_i[)
- \$(DX_V_DXGEN)\$(DX_ENV) DOCDIR=\$(DX_DOCDIR]DX_i[) \$(DX_DOXYGEN) \$(DX_CONFIG]DX_i[)
- \$(A""M_V_at)echo Timestamp >\$][@
-
-]])dnl
-[DX_CLEANFILES = \\]
-m4_foreach([DX_i], [DX_loop],
-[[ \$(DX_DOCDIR]DX_i[)/doxygen_sqlite3.db \\
- \$(DX_DOCDIR]DX_i[)/\$(PACKAGE).tag \\
-]])dnl
-[ -r \\
- \$(DX_CLEAN_HTML) \\
- \$(DX_CLEAN_CHM) \\
- \$(DX_CLEAN_CHI) \\
- \$(DX_CLEAN_MAN) \\
- \$(DX_CLEAN_RTF) \\
- \$(DX_CLEAN_XML) \\
- \$(DX_CLEAN_PS) \\
- \$(DX_CLEAN_PDF) \\
- \$(DX_CLEAN_LATEX)"]],
-[[DX_SNIPPET_doc=""]])
-AC_SUBST([DX_RULES],
-["${DX_SNIPPET_doc}"])dnl
-AM_SUBST_NOTMAKE([DX_RULES])
-
-#For debugging:
-#echo DX_FLAG_doc=$DX_FLAG_doc
-#echo DX_FLAG_dot=$DX_FLAG_dot
-#echo DX_FLAG_man=$DX_FLAG_man
-#echo DX_FLAG_html=$DX_FLAG_html
-#echo DX_FLAG_chm=$DX_FLAG_chm
-#echo DX_FLAG_chi=$DX_FLAG_chi
-#echo DX_FLAG_rtf=$DX_FLAG_rtf
-#echo DX_FLAG_xml=$DX_FLAG_xml
-#echo DX_FLAG_pdf=$DX_FLAG_pdf
-#echo DX_FLAG_ps=$DX_FLAG_ps
-#echo DX_ENV=$DX_ENV
-])
diff --git a/m4/libcurl.m4 b/m4/libcurl.m4
@@ -1,251 +0,0 @@
-# LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
-# [ACTION-IF-YES], [ACTION-IF-NO])
-# ----------------------------------------------------------
-# David Shaw <dshaw@jabberwocky.com> May-09-2006
-#
-# Checks for libcurl. DEFAULT-ACTION is the string yes or no to
-# specify whether to default to --with-libcurl or --without-libcurl.
-# If not supplied, DEFAULT-ACTION is yes. MINIMUM-VERSION is the
-# minimum version of libcurl to accept. Pass the version as a regular
-# version number like 7.10.1. If not supplied, any version is
-# accepted. ACTION-IF-YES is a list of shell commands to run if
-# libcurl was successfully found and passed the various tests.
-# ACTION-IF-NO is a list of shell commands that are run otherwise.
-# Note that using --without-libcurl does run ACTION-IF-NO.
-#
-# This macro #defines HAVE_LIBCURL if a working libcurl setup is
-# found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
-# values. Other useful defines are LIBCURL_FEATURE_xxx where xxx are
-# the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
-# where yyy are the various protocols supported by libcurl. Both xxx
-# and yyy are capitalized. See the list of AH_TEMPLATEs at the top of
-# the macro for the complete list of possible defines. Shell
-# variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
-# defined to 'yes' for those features and protocols that were found.
-# Note that xxx and yyy keep the same capitalization as in the
-# curl-config list (e.g. it's "HTTP" and not "http").
-#
-# Users may override the detected values by doing something like:
-# LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
-#
-# For the sake of sanity, this macro assumes that any libcurl that is
-# found is after version 7.7.2, the first version that included the
-# curl-config script. Note that it is very important for people
-# packaging binary versions of libcurl to include this script!
-# Without curl-config, we can only guess what protocols are available,
-# or use curl_version_info to figure it out at runtime.
-
-AC_DEFUN([LIBCURL_CHECK_CONFIG],
-[
- AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
- AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
- AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
- AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
- AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
- AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
- AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
- AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
-
- AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
- AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
- AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
- AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
- AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
- AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_RTSP],[Defined if libcurl supports RTSP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_POP3],[Defined if libcurl supports POP3])
- AH_TEMPLATE([LIBCURL_PROTOCOL_IMAP],[Defined if libcurl supports IMAP])
- AH_TEMPLATE([LIBCURL_PROTOCOL_SMTP],[Defined if libcurl supports SMTP])
-
- AC_ARG_WITH(libcurl,
- AS_HELP_STRING([--with-libcurl=PREFIX],[look for the curl library in PREFIX/lib and headers in PREFIX/include]),
- [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
-
- if test "$_libcurl_with" != "no" ; then
-
- AC_PROG_AWK
-
- _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
-
- _libcurl_try_link=yes
-
- if test -d "$_libcurl_with" ; then
- LIBCURL_CPPFLAGS="-I$withval/include"
- _libcurl_ldflags="-L$withval/lib"
- AC_PATH_PROG([_libcurl_config],[curl-config],[],
- ["$withval/bin"])
- else
- AC_PATH_PROG([_libcurl_config],[curl-config],[],[$PATH])
- fi
-
- if test x$_libcurl_config != "x" ; then
- AC_CACHE_CHECK([for the version of libcurl],
- [libcurl_cv_lib_curl_version],
- [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
-
- _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
- _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
-
- if test $_libcurl_wanted -gt 0 ; then
- AC_CACHE_CHECK([for libcurl >= version $2],
- [libcurl_cv_lib_version_ok],
- [
- if test $_libcurl_version -ge $_libcurl_wanted ; then
- libcurl_cv_lib_version_ok=yes
- else
- libcurl_cv_lib_version_ok=no
- fi
- ])
- fi
-
- if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
- if test x"$LIBCURL_CPPFLAGS" = "x" ; then
- LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
- fi
- if test x"$LIBCURL" = "x" ; then
- LIBCURL=`$_libcurl_config --libs`
-
- # This is so silly, but Apple actually has a bug in their
- # curl-config script. Fixed in Tiger, but there are still
- # lots of Panther installs around.
- case "${host}" in
- powerpc-apple-darwin7*)
- LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
- ;;
- esac
- fi
-
- # All curl-config scripts support --feature
- _libcurl_features=`$_libcurl_config --feature`
-
- # Is it modern enough to have --protocols? (7.12.4)
- if test $_libcurl_version -ge 461828 ; then
- _libcurl_protocols=`$_libcurl_config --protocols`
- fi
- else
- _libcurl_try_link=no
- fi
-
- unset _libcurl_wanted
- fi
-
- if test $_libcurl_try_link = yes ; then
-
- # we didn't find curl-config, so let's see if the user-supplied
- # link line (or failing that, "-lcurl") is enough.
- LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
-
- AC_CACHE_CHECK([whether libcurl is usable],
- [libcurl_cv_lib_curl_usable],
- [
- _libcurl_save_cppflags=$CPPFLAGS
- CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
- _libcurl_save_libs=$LIBS
- LIBS="$LIBCURL $LIBS"
-
- AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
-/* Try and use a few common options to force a failure if we are
- missing symbols or can't link. */
-int x;
-curl_easy_setopt(NULL,CURLOPT_URL,NULL);
-x=CURL_ERROR_SIZE;
-x=CURLOPT_WRITEFUNCTION;
-x=CURLOPT_WRITEDATA;
-x=CURLOPT_ERRORBUFFER;
-x=CURLOPT_STDERR;
-x=CURLOPT_VERBOSE;
-if (x) ;
-]])],libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
-
- CPPFLAGS=$_libcurl_save_cppflags
- LIBS=$_libcurl_save_libs
- unset _libcurl_save_cppflags
- unset _libcurl_save_libs
- ])
-
- if test $libcurl_cv_lib_curl_usable = yes ; then
-
- # Does curl_free() exist in this version of libcurl?
- # If not, fake it with free()
-
- _libcurl_save_cppflags=$CPPFLAGS
- CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
- _libcurl_save_libs=$LIBS
- LIBS="$LIBS $LIBCURL"
-
- AC_CHECK_FUNC(curl_free,,
- AC_DEFINE(curl_free,free,
- [Define curl_free() as free() if our version of curl lacks curl_free.]))
-
- CPPFLAGS=$_libcurl_save_cppflags
- LIBS=$_libcurl_save_libs
- unset _libcurl_save_cppflags
- unset _libcurl_save_libs
-
- AC_DEFINE(HAVE_LIBCURL,1,
- [Define to 1 if you have a functional curl library.])
- AC_SUBST(LIBCURL_CPPFLAGS)
- AC_SUBST(LIBCURL)
-
- for _libcurl_feature in $_libcurl_features ; do
- AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
- eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
- done
-
- if test "x$_libcurl_protocols" = "x" ; then
-
- # We don't have --protocols, so just assume that all
- # protocols are available
- _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT TFTP"
-
- if test x$libcurl_feature_SSL = xyes ; then
- _libcurl_protocols="$_libcurl_protocols HTTPS"
-
- # FTPS wasn't standards-compliant until version
- # 7.11.0 (0x070b00 == 461568)
- if test $_libcurl_version -ge 461568; then
- _libcurl_protocols="$_libcurl_protocols FTPS"
- fi
- fi
-
- # RTSP, IMAP, POP3 and SMTP were added in
- # 7.20.0 (0x071400 == 463872)
- if test $_libcurl_version -ge 463872; then
- _libcurl_protocols="$_libcurl_protocols RTSP IMAP POP3 SMTP"
- fi
- fi
-
- for _libcurl_protocol in $_libcurl_protocols ; do
- AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
- eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
- done
- else
- unset LIBCURL
- unset LIBCURL_CPPFLAGS
- fi
- fi
-
- unset _libcurl_try_link
- unset _libcurl_version_parse
- unset _libcurl_config
- unset _libcurl_feature
- unset _libcurl_features
- unset _libcurl_protocol
- unset _libcurl_protocols
- unset _libcurl_version
- unset _libcurl_ldflags
- fi
-
- if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
- # This is the IF-NO path
- ifelse([$4],,:,[$4])
- else
- # This is the IF-YES path
- ifelse([$3],,:,[$3])
- fi
-
- unset _libcurl_with
-])dnl
diff --git a/m4/mhd2.m4 b/m4/mhd2.m4
@@ -1,50 +0,0 @@
-# mhd2.m4
-
-# This file is part of GNU libmicrohttpd
-# Copyright (C) 2025 Taler Systems SA
-#
-# GNU libmicrohttpd is free software; you can redistribute it and/or modify it under the
-# terms of the GNU Lesser General Public License as published by the Free Software
-# Foundation; either version 3, or (at your option) any later version.
-#
-# GNU libmicrohttpd is distributed in the hope that it will be useful, but WITHOUT ANY
-# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
-# A PARTICULAR PURPOSE. See the GNU General Public License for more details.
-#
-# You should have received a copy of the GNU Lesser General Public License along with
-# GNU libmicrohttpd; see the file COPYING. If not, If not, see <http://www.gnu.org/license>
-
-# serial 1
-
-dnl MHD2_VERSION_AT_LEAST([VERSION])
-dnl
-dnl Check that microhttpd2.h can be used to build a program that prints out
-dnl the MHD_VERSION tuple in X.Y.Z format, and that X.Y.Z is greater or equal
-dnl to VERSION. If not, display message and cause the configure script to
-dnl exit failurefully.
-dnl
-dnl This uses AX_COMPARE_VERSION to do the job.
-dnl It sets shell var mhd_cv_version, as well.
-dnl
-AC_DEFUN([MHD2_VERSION_AT_LEAST],
- [AC_CACHE_CHECK([libmicrohttpd2 version],[mhd2_cv_version],
- [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
- #include <stdio.h>
- #include <microhttpd2.h>
-]],[[
- int v = MHD_VERSION;
- printf ("%x.%x.%x\n",
- (v >> 24) & 0xff,
- (v >> 16) & 0xff,
- (v >> 8) & 0xff);
-]])],
- [mhd2_cv_version=$(./conftest)],
- [mhd2_cv_version=0])])
-AX_COMPARE_VERSION([$mhd2_cv_version],[ge],[$1],
- [libmhd2=1],
- [libmhd2=0])
-AM_CONDITIONAL([HAVE_MHD2], [test "x$libmhd2" = "x1"])
-AC_DEFINE_UNQUOTED([HAVE_MHD2], [$libmhd2],
- [Defined to 1 if libmicrohttpd2 is available])
-])
-# mhd2.m4 ends here
diff --git a/src/Makefile.am b/src/Makefile.am
@@ -1,4 +0,0 @@
-# This Makefile is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-SUBDIRS = include util syncdb sync lib testing
-
diff --git a/src/include/Makefile.am b/src/include/Makefile.am
@@ -1,5 +0,0 @@
-# This Makefile.am is in the public domain
-SUBDIRS = . sync
-
-EXTRA_DIST = \
- platform.h
diff --git a/src/include/sync/Makefile.am b/src/include/sync/Makefile.am
@@ -1,10 +0,0 @@
-# This Makefile.am is in the public domain
-SUBDIRS = . sync-database
-
-syncincludedir = $(includedir)/sync
-
-syncinclude_HEADERS = \
- sync_database_lib.h \
- sync_service.h \
- sync_testing_lib.h \
- sync_util.h
diff --git a/src/include/sync/sync-database/Makefile.am b/src/include/sync/sync-database/Makefile.am
@@ -1,18 +0,0 @@
-# This Makefile.am is in the public domain
-SUBDIRS = .
-
-syncdbincludedir = $(includedir)/sync/sync-database
-
-syncdbinclude_HEADERS = \
- create_tables.h \
- common.h \
- drop_tables.h \
- gc.h \
- increment_lifetime_TR.h \
- lookup_account_TR.h \
- lookup_backup_TR.h \
- lookup_pending_payments_by_account_TR.h \
- preflight.h \
- store_backup_TR.h \
- store_payment_TR.h \
- update_backup_TR.h
diff --git a/src/lib/Makefile.am b/src/lib/Makefile.am
@@ -1,28 +0,0 @@
-# This Makefile.am is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-
-if USE_COVERAGE
- AM_CFLAGS = --coverage -O0
- XLIB = -lgcov
-endif
-
-lib_LTLIBRARIES = \
- libsync.la
-
-libsync_la_LDFLAGS = \
- -version-info 0:1:0 \
- -no-undefined
-libsync_la_SOURCES = \
- sync_api_curl_defaults.c sync_api_curl_defaults.h \
- sync_api_download.c \
- sync_api_upload.c
-libsync_la_LIBADD = \
- -lgnunetcurl \
- -lgnunetjson \
- -ltalerjson \
- -ltalercurl \
- -ltalerutil \
- -lgnunetutil \
- -ljansson \
- -lcurl \
- $(XLIB)
diff --git a/src/sync/Makefile.am b/src/sync/Makefile.am
@@ -1,63 +0,0 @@
-# This Makefile.am is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-
-if USE_COVERAGE
- AM_CFLAGS = --coverage -O0
- XLIB = -lgcov
-endif
-
-pkgcfgdir = $(prefix)/share/sync/config.d/
-
-pkgcfg_DATA = \
- sync.conf
-
-bin_PROGRAMS = \
- sync-httpd
-
-if HAVE_MHD2
-# Experimental port to libmicrohttpd2
-bin_PROGRAMS += \
- sync-httpd2
-endif
-
-sync_httpd_SOURCES = \
- sync-httpd.c sync-httpd.h \
- sync-httpd_backup.c sync-httpd_backup.h \
- sync-httpd_backup_post.c \
- sync-httpd_config.c sync-httpd_config.h \
- sync-httpd_mhd.c sync-httpd_mhd.h
-sync_httpd_LDADD = \
- $(top_builddir)/src/util/libsyncutil.la \
- $(top_builddir)/src/syncdb/libsyncdb.la \
- -lmicrohttpd \
- -ljansson \
- -ltalermerchant \
- -ltalermhd \
- -ltalerjson \
- -ltalerutil \
- -lgnunetcurl \
- -lgnunetjson \
- -lgnunetutil \
- $(XLIB)
-
-sync_httpd2_SOURCES = \
- sync-httpd2.c sync-httpd2.h \
- sync-httpd2_backup.c sync-httpd2_backup.h \
- sync-httpd2_backup-post.c \
- sync-httpd2_config.c sync-httpd2_config.h
-sync_httpd2_LDADD = \
- $(top_builddir)/src/util/libsyncutil.la \
- $(top_builddir)/src/syncdb/libsyncdb.la \
- -lmicrohttpd2 \
- -ljansson \
- -ltalermerchant \
- -ltalermhd2 \
- -ltalerjson \
- -ltalerutil \
- -lgnunetcurl \
- -lgnunetjson \
- -lgnunetutil \
- $(XLIB)
-
-EXTRA_DIST = \
- $(pkgcfg_DATA)
diff --git a/src/syncdb/Makefile.am b/src/syncdb/Makefile.am
@@ -1,104 +0,0 @@
-# This Makefile.am is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-
-pkgcfgdir = $(prefix)/share/sync/config.d/
-
-pkgcfg_DATA = \
- sync_db_postgres.conf
-
-if USE_COVERAGE
- AM_CFLAGS = --coverage -O0
- XLIB = -lgcov
-endif
-
-sqldir = $(prefix)/share/sync/sql/
-
-sqlinputs = \
- syncdb_increment_lifetime_TR.sql \
- syncdb_lookup_account_TR.sql \
- syncdb_lookup_backup_TR.sql \
- syncdb_lookup_pending_payments_by_account_TR.sql \
- syncdb_store_backup_TR.sql \
- syncdb_store_payment_TR.sql \
- syncdb_update_backup_TR.sql \
- procedures.sql.in
-
-sql_DATA = \
- versioning.sql \
- procedures.sql \
- sync-0001.sql \
- drop.sql
-
-BUILT_SOURCES = \
- procedures.sql
-
-procedures.sql: procedures.sql.in syncdb_*_TR.sql
- chmod +w $@ || true
- gcc -E -P -undef - < procedures.sql.in 2>/dev/null | sed -e "s/--.*//" | awk 'NF' - >$@
- chmod ugo-w $@
-
-bin_PROGRAMS = \
- sync-dbinit
-
-sync_dbinit_SOURCES = \
- sync-dbinit.c
-sync_dbinit_LDADD = \
- $(LIBGCRYPT_LIBS) \
- $(top_builddir)/src/util/libsyncutil.la \
- libsyncdb.la \
- -ltalerpq \
- -ltalerutil \
- -lgnunetpq \
- -lgnunetutil \
- -lpq \
- $(XLIB)
-
-lib_LTLIBRARIES = \
- libsyncdb.la
-libsyncdb_la_SOURCES = \
- syncdb_pg.c syncdb_pg.h \
- syncdb_drop_tables.c \
- syncdb_create_tables.c \
- syncdb_preflight.c \
- syncdb_gc.c \
- syncdb_store_payment_TR.c \
- syncdb_lookup_pending_payments_by_account_TR.c \
- syncdb_store_backup_TR.c \
- syncdb_update_backup_TR.c \
- syncdb_lookup_account_TR.c \
- syncdb_lookup_backup_TR.c \
- syncdb_increment_lifetime_TR.c
-libsyncdb_la_LIBADD = \
- $(top_builddir)/src/util/libsyncutil.la \
- -ltalerpq \
- -lgnunetpq \
- -lpq \
- -lgnunetutil \
- $(XLIB)
-libsyncdb_la_LDFLAGS = \
- $(POSTGRESQL_LDFLAGS) \
- -version-info 1:0:0 \
- -no-undefined
-
-check_PROGRAMS = \
- $(TESTS)
-
-test_sync_db_postgres_SOURCES = \
- test_sync_db.c
-test_sync_db_postgres_LDFLAGS = \
- $(top_builddir)/src/util/libsyncutil.la \
- libsyncdb.la \
- -lgnunetutil \
- -lgnunetpq \
- -ltalerutil \
- $(XLIB)
-
-AM_TESTS_ENVIRONMENT=export SYNC_PREFIX=$${SYNC_PREFIX:-@libdir@};export PATH=$${SYNC_PREFIX:-@prefix@}/bin:$$PATH;
-TESTS = \
- test_sync_db-postgres
-
-EXTRA_DIST = \
- $(pkgcfg_DATA) \
- $(sql_DATA) \
- $(sqlinputs) \
- test_sync_db_postgres.conf
diff --git a/src/testing/Makefile.am b/src/testing/Makefile.am
@@ -1,61 +0,0 @@
-# This Makefile.am is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include
-
-if USE_COVERAGE
- AM_CFLAGS = --coverage -O0
- XLIB = -lgcov
-endif
-
-lib_LTLIBRARIES = \
- libsynctesting.la
-
-libsynctesting_la_LDFLAGS = \
- -version-info 0:1:0 \
- -no-undefined
-libsynctesting_la_SOURCES = \
- testing_api_cmd_backup_download.c \
- testing_api_cmd_backup_upload.c \
- testing_api_traits.c
-libsynctesting_la_LIBADD = \
- $(top_builddir)/src/lib/libsync.la \
- -ltalermerchant \
- -ltalerexchange \
- -ltalerjson \
- -ltalerutil \
- -lgnunetcurl \
- -lgnunetjson \
- -lgnunetutil \
- -ljansson \
- -ltalertesting \
- $(XLIB)
-
-AM_TESTS_ENVIRONMENT=export SYNC_PREFIX=$${SYNC_PREFIX:-@libdir@};export PATH=$${SYNC_PREFIX:-@prefix@}/bin:$$PATH;
-
-check_PROGRAMS = \
- test_sync_api
-
-TESTS = \
- $(check_PROGRAMS)
-
-EXTRA_DIST = \
- test_sync_api.conf \
- test_sync_api_home/.local/share/taler/exchange-offline/master.priv
-
-test_sync_api_SOURCES = \
- test_sync_api.c
-test_sync_api_LDADD = \
- $(top_builddir)/src/lib/libsync.la \
- libsynctesting.la \
- -ltalertesting \
- -ltalermerchanttesting \
- -ltalerfakebank \
- -ltalerbank \
- -ltalerexchange \
- -ltalermerchant \
- -ltalerjson \
- -ltalerutil \
- -lgnunetjson \
- -lgnunetcurl \
- -lgnunetutil \
- -ljansson \
- $(XLIB)
diff --git a/src/util/Makefile.am b/src/util/Makefile.am
@@ -1,39 +0,0 @@
-# This Makefile.am is in the public domain
-AM_CPPFLAGS = -I$(top_srcdir)/src/include $(LIBGCRYPT_CFLAGS)
-
-if USE_COVERAGE
- AM_CFLAGS = --coverage -O0
- XLIB = -lgcov
-endif
-
-
-pkgcfgdir = $(prefix)/share/sync/config.d/
-
-pkgcfg_DATA = \
- paths.conf
-
-bin_PROGRAMS = \
- sync-config
-
-sync_config_SOURCES = \
- sync-config.c
-sync_config_LDADD = \
- libsyncutil.la \
- -lgnunetutil \
- $(XLIB)
-
-EXTRA_DIST = \
- $(bin_SCRIPTS) \
- $(pkgcfg_DATA)
-
-lib_LTLIBRARIES = \
- libsyncutil.la
-
-libsyncutil_la_SOURCES = \
- os_installation.c
-libsyncutil_la_LIBADD = \
- -lgnunetutil \
- $(XLIB)
-libsyncutil_la_LDFLAGS = \
- -version-info 0:1:0 \
- -export-dynamic -no-undefined
