1 files changed, 59 insertions, 59 deletions

diff --git a/configure.ac b/configure.ac
index 40a35c2..5b4422a 100644
--- a/configure.ac
+++ b/configure.ac
@@ -155,12 +155,9 @@ mingw*)
                 EXT_LIB_PATH="-L$with_plibc/lib $EXT_LIB_PATH"
                 plibc=1))])
 
-     if test $plibc -ne 1;
-     then
-        AC_MSG_ERROR([libextractor requires PlibC])
-     else
-        LIBS="$LIBS -lplibc"
-     fi
+     AS_IF([test $plibc -ne 1],
+           [AC_MSG_ERROR([libextractor requires PlibC])],
+           [LIBS="$LIBS -lplibc"])
 
      AM_LDFLAGS="$AM_LDFLAGS -Wl,--export-all-symbols"
      AM_CONDITIONAL(HAVE_GNU_LD, true)
@@ -211,10 +208,8 @@ AM_CONDITIONAL(MINGW, test "$build_os" = "mingw32")
 
 
 # use '-fno-strict-aliasing', but only if the compiler can take it
-if gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1;
-then
- AM_CFLAGS="-fno-strict-aliasing $AM_CFLAGS"
-fi
+AS_IF([gcc -fno-strict-aliasing -S -o /dev/null -xc /dev/null >/dev/null 2>&1],
+      [AM_CFLAGS="-fno-strict-aliasing $AM_CFLAGS"])
 
 AM_CONDITIONAL(HAVE_CXX, test "x$HAVE_CXX" = "xyes")
 
@@ -222,27 +217,47 @@ AM_CONDITIONAL(HAVE_CXX, test "x$HAVE_CXX" = "xyes")
 # Adam shostack suggests the following for Windows:
 # -D_FORTIFY_SOURCE=2 -fstack-protector-all
 AC_ARG_ENABLE(gcc-hardening,
-   AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
-[if test x$enableval = xyes; then
-    AM_CFLAGS="$AM_CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
-    AM_CFLAGS="$AM_CFLAGS -fwrapv -fPIE -Wstack-protector"
-    AM_CFLAGS="$AM_CFLAGS --param ssp-buffer-size=1"
-    AM_LDFLAGS="$AM_LDFLAGS -pie"
-fi])
+  [AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks)],
+  [AS_IF([test x$enableval = xyes],
+         [AM_CFLAGS="$AM_CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
+          AM_CFLAGS="$AM_CFLAGS -fwrapv -fPIE -Wstack-protector"
+          AM_CFLAGS="$AM_CFLAGS --param ssp-buffer-size=1"
+          AM_LDFLAGS="$AM_LDFLAGS -pie"])])
 
 
 # Linker hardening options
 # Currently these options are ELF specific - you can't use this with MacOSX
 AC_ARG_ENABLE(linker-hardening,
-  AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
-[if test x$enableval = xyes; then
-   AM_LDFLAGS="$AM_LDFLAGS -z relro -z now"
-fi])
+  [AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups)],
+  [AS_IF([x$enableval = xyes],
+         [AM_LDFLAGS="$AM_LDFLAGS -z relro -z now"])])
+
+
+# Support for hiding non-public symbols
+HIDDEN_VISIBILITY_CFLAGS=""
+case "$host" in
+  *-*-mingw*)
+    dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
+    AC_DEFINE([_EXTRACTOR_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
+              [defines how to decorate public symbols while building])
+    HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
+    ;;
+  *)
+    dnl on other compilers, check if we can do -fvisibility=hidden
+    AX_CHECK_LINK_FLAG([-fvisibility=hidden],
+      [AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],
+                           [AC_DEFINE([_EXTRACTOR_EXTERN], [__attribute__((visibility("default"))) extern],
+                                       [defines how to decorate public symbols while building])
+                            HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"])])
+    ;;
+esac
+AC_SUBST(HIDDEN_VISIBILITY_CFLAGS)
+
 
 
 # Checks for libraries.
 
-AC_CHECK_HEADERS(langinfo.h)
+AC_CHECK_HEADERS([langinfo.h])
 
 # Check for libltdl header (#2999)
 ltdl=0
@@ -274,12 +289,9 @@ AC_ARG_WITH(ltdl,
     AC_CHECK_HEADERS(ltdl.h,
      AC_CHECK_LIB([ltdl], [lt_dlopenext],
       ltdl=1))])
-if test x$ltdl = x1
-then
- AC_MSG_RESULT([libltdl found])
-else
- AC_MSG_ERROR([libextractor requires libltdl (from GNU libtool), try installing libltdl-dev])
-fi
+AS_IF([test x$ltdl = x1],
+      [AC_MSG_RESULT([libltdl found])],
+      [AC_MSG_ERROR([libextractor requires libltdl (from GNU libtool), try installing libltdl-dev])])
 
 # check for apparmor
 AC_CHECK_LIB(apparmor, aa_change_profile,
@@ -542,10 +554,8 @@ AC_LINK_IFELSE(
 LIBS="$SAVED_LIBS $SOCKET_LIBS"
 AC_LANG_POP(C)
 AC_MSG_RESULT([$sockets])
-if test "x$sockets" = "xno"
-then
-  AC_MSG_ERROR([libextractor requires some kind of socket library])
-fi
+AS_IF([test "x$sockets" = "xno"],
+      [AC_MSG_ERROR([libextractor requires some kind of socket library])])
 AC_SUBST([SOCKET_LIBS],[$SOCKET_LIBS])
 
 LE_LIB_LIBS=$LIBS
@@ -574,22 +584,16 @@ AC_ARG_ENABLE(glib,
    esac],
   AC_MSG_RESULT(allowed))
 
-if test x$without_glib != xtrue
-then
-  if test $with_gnu_ld = yes
-  then
-# We need both GNU LD and GLIB here!
-    AM_CONDITIONAL(HAVE_GLIB,true)
-    AC_DEFINE(HAVE_GLIB, 1, [Have glib])
-  else
-# We may have GLIB, but without GNU LD we must not use it!
-    AM_CONDITIONAL(HAVE_GLIB,false)
-    AC_DEFINE(HAVE_GLIB, 0, [Have glib, but not GNU LD])
-  fi
-else
- AM_CONDITIONAL(HAVE_GLIB,false)
- AC_DEFINE(HAVE_GLIB, 0, [Have glib])
-fi
+AS_IF([test x$without_glib != xtrue],
+      [AS_IF([test $with_gnu_ld = yes],
+             [# We need both GNU LD and GLIB here!
+              AM_CONDITIONAL(HAVE_GLIB,true)
+              AC_DEFINE(HAVE_GLIB, 1, [Have glib])],
+             [# We may have GLIB, but without GNU LD we must not use it!
+              AM_CONDITIONAL(HAVE_GLIB,false)
+              AC_DEFINE(HAVE_GLIB, 0, [Have glib, but not GNU LD])])],
+     [AM_CONDITIONAL(HAVE_GLIB,false)
+      AC_DEFINE(HAVE_GLIB, 0, [Have glib])])
 
 # smf requires glib.h
 CFLAGS_OLD="$CFLAGS"
@@ -609,13 +613,10 @@ AC_MSG_CHECKING(for gdk-pixbuf)
 PKG_CHECK_MODULES([GDK_PIXBUF], [gdk-pixbuf-2.0 >= 2.4], [have_gdk_pixbuf=yes], [have_gdk_pixbuf=no])
 
 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test x$have_gdk_pixbuf != xno)
-if test $have_gdk_pixbuf != no
-then
-  have_gdk_pixbuf=1
-else
-  have_gdk_pixbuf=0
-  AC_MSG_NOTICE([Cannot find Gdk-pixbuf: Is pkg-config in path?])
-fi
+AS_IF([test $have_gdk_pixbuf != no],
+      [have_gdk_pixbuf=1],
+      [have_gdk_pixbuf=0
+      AC_MSG_NOTICE([Cannot find Gdk-pixbuf: Is pkg-config in path?])])
 AC_DEFINE_UNQUOTED([HAVE_GDK_PIXBUF], [$have_gdk_pixbuf], [We have Gdk-pixbuf])
 
 CFLAGS="$CFLAGS $GDK_PIXBUF_CFLAGS"
@@ -670,9 +671,8 @@ AC_ARG_ENABLE(ffmpeg,
   esac],
   [     AC_MSG_RESULT(yes)
         ffmpeg_enabled=1])
-if test x$ffmpeg_enabled = x1
-then
-  ffmpeg_enabled=0
+AS_IF([test x$ffmpeg_enabled = x1],
+ [ffmpeg_enabled=0
   new_ffmpeg=0
   AC_CHECK_HEADERS([libavutil/avutil.h libavformat/avformat.h libavcodec/avcodec.h libavutil/frame.h],
     AC_CHECK_HEADERS([libavresample/avresample.h],
@@ -683,7 +683,7 @@ then
     AC_CHECK_LIB(avcodec, avcodec_alloc_context3,
       ffmpeg_enabled=1))
   AC_CHECK_HEADERS([libavutil/avutil.h ffmpeg/avutil.h libavformat/avformat.h ffmpeg/avformat.h libavcodec/avcodec.h ffmpeg/avcodec.h libswscale/swscale.h ffmpeg/swscale.h])
-fi
+ ])
 AM_CONDITIONAL(HAVE_FFMPEG, test x$ffmpeg_enabled != x0)
 AM_CONDITIONAL(HAVE_FFMPEG_NEW, test x$new_ffmpeg != x0)