path: root/qml/main.qml

import QtQuick 2.1
import QtQuick.Window 2.1
import QtQuick.Layouts 1.1
import QtQuick.Controls 1.2
import QtQuick.Controls.Styles 1.2

import secushare 1.0

ApplicationWindow {
    opacity: App.connected ? 1 : 0.25

    onClosing: {
        close.accepted = false
        App.close()
    }

    id: root

    width: 1000
    height: 700
    color: "white"

    property int noTab: -1

    property int threadListTab: 0
    property int enterPlaceTab: 1
    property int createHomeTab: 2
    property int createEgoTab: 3
    property int threadTab: 4
    property int profileTab: 5
    property int prefsTab: 6

    property int leftPlacesTab: 0

    property int rightThreadsTab: 0
    property int rightNymsTab: 1
    property int rightEgosTab: 2

    property var selectedPlace: null
    property var selectedThread: null

    FontLoader { id: bebasFont; source: "fonts/BebasNeue.otf" }
    FontLoader { id: ubuntuFont; source: "fonts/Ubuntu-R.ttf" }
    FontLoader { id: ubuntuBIFont; source: "fonts/Ubuntu-BI.ttf" }

    RowLayout {
        anchors.fill: parent
        spacing: 0

        Rectangle {
            id: leftSide
            width: 200
            Layout.fillHeight: true
            color: Settings.leftSideColor

            ColumnLayout {
                width: parent.width - 8
                height: parent.height

                anchors.top: parent.top
                anchors.left: parent.left

                anchors.topMargin: 8
                anchors.bottomMargin: 8
                anchors.leftMargin: 8
                anchors.rightMargin: 0

                spacing: 0

                Rectangle {
                    id: logoButton
                    width: parent.width
                    height: 60
                    color: threadListTab == main.currentIndex ? "white" : "transparent"

                    Rectangle {
                        width: parent.width - 8
                        height: parent.height

                        Image {
                            anchors.horizontalCenter: parent.horizontalCenter
                            height: parent.height
                            source: "images/logo.png"
                            fillMode: Image.PreserveAspectFit
                            opacity: App.connected ? 1 : 0.25
                        }
                    }

                    MouseArea {
                        anchors.fill: parent
                        onClicked: {
                            main.currentIndex = threadListTab
                        }
                    }
                }

                Rectangle { height: 10 }

                RowLayout {
                    anchors.left: parent.left
                    width: parent.width - 8
                    spacing: 0

                    Rectangle {
                        height: 30
                        width: parent.width
                        color: "white"

                        Text {
                            text: qsTr("PLACES")
                            color: "black"
                            anchors.centerIn: parent
                            font.pointSize: 22
                            font.family: bebasFont.name
                        }
                    }
                }

                TabView {
                    id: left
                    Layout.fillHeight: true
                    Layout.fillWidth: true

                    focus: true
                    tabsVisible: false
                    frameVisible: false

                    currentIndex: leftPlacesTab

                    onCurrentIndexChanged: {
                        console.log("left tabview index changed:", currentIndex)

                        switch (currentIndex)
                        {
                            case leftPlacesTab:
                                if (0 <= placeListTab.currentIndex)
                                {
                                    main.currentIndex = placeListTab.currentIndex
                                }
                                break;
                        }
                    }

                    Tab {
                        id: placeListTab
                        active: true
                        property int currentIndex: -1

                        SidePlaceList {
                            id: placeList
                            anchors.fill: parent
                            width: 200 - 8
                            mainIndex: main.currentIndex

                            onCurrentIndexChanged:
                            {
                                placeListTab.currentIndex = currentIndex
                                main.currentIndex = currentIndex
                            }

                            onSelectedPlaceChanged:
                            {
                                console.log("selected place changed:", selectedPlace)
                                root.selectedPlace = selectedPlace
                                if (selectedPlace)
                                {
                                    main.currentIndex = profileTab
                                }
                            }
                        }
                    }
                }

                Rectangle { height: 10 }

                Rectangle {
                    width: parent.width
                    height: 30
                    color: prefsTab == main.currentIndex ? "white" : "transparent"

                    Rectangle {
                        width: parent.width - 8
                        height: parent.height
                        color: "white"

                        Image {
                            height: 24
                            anchors.centerIn: parent
                            source: "images/settings-black.png"
                            fillMode: Image.PreserveAspectFit
                        }
                    }

                    MouseArea {
                        anchors.fill: parent
                        onClicked: main.currentIndex = prefsTab
                    }
                }

                Rectangle { height: 15 }
            }
        }

        TabView {
            id: main
            Layout.fillWidth: true
            Layout.fillHeight: true

            focus: true
            tabsVisible: false
            frameVisible: false

            currentIndex: threadListTab

            onCurrentIndexChanged: {
                console.log("main index changed:", currentIndex)

                if (profileTab != currentIndex
                    && threadTab != currentIndex)
                {
                        placeListTab.currentIndex = noTab
                }
            }

            Tab {
                ThreadList {
                    anchors.fill: parent

                    onCurrentIndexChanged:
                    {
                        placeListTab.currentIndex = currentIndex
                        main.currentIndex = currentIndex
                    }

                    onSelectedThreadChanged: {
                        console.log("selected thread changed:", selectedThread)
                        root.selectedThread = selectedThread
                        if (selectedThread)
                        {
                            main.currentIndex = threadTab
                        }
                    }
                }
            }

            Tab {
                PlaceEnter {
                    anchors.fill: parent
                }
            }

            Tab {
                PlaceCreate {
                    anchors.fill: parent
                }
            }

            Tab {
                EgoCreate {
                    anchors.fill: parent
                }
            }

            Tab {
                PlaceThread {
                    anchors.fill: parent
                    thread: selectedThread
                }
            }

            Tab {
                Profile {
                    anchors.fill: parent
                    place: selectedPlace
                }
            }

            Tab {
                Prefs {
                    anchors.fill: parent
                }
            }
        }

        Rectangle {
            id: rightSide
            width: 200
            Layout.fillHeight: true
            color: Settings.rightSideColor
            visible: profileTab == main.currentIndex || threadTab == main.currentIndex

            ColumnLayout {
                width: parent.width - 8
                height: parent.height

                anchors.top: parent.top
                anchors.right: parent.right

                anchors.topMargin: 8
                anchors.bottomMargin: 8
                anchors.leftMargin: 0
                anchors.rightMargin: 8

                spacing: 0

                RowLayout {
                    anchors.right: parent.right
                    width: parent.width - 8
                    spacing: 0

                    Rectangle {
                        height: 30
                        width: parent.width / 2
                        color: right.currentIndex == rightThreadsTab ? "white" : "black"

                        Image {
                            height: parent.height - 4
                            anchors.centerIn: parent
                            fillMode: Image.PreserveAspectFit
                            source: right.currentIndex == rightThreadsTab ? "images/thread_dark.png" : "images/thread.png"
                        }

                        MouseArea {
                            anchors.fill: parent
                            onClicked: {
                                right.currentIndex = rightThreadsTab
                            }
                        }
                    }

                    Rectangle {
                        height: 30
                        width: parent.width / 2
                        color: right.currentIndex == rightNymsTab ? "white" : "black"

                        Image {
                            height: parent.height - 4
                            anchors.centerIn: parent
                            fillMode: Image.PreserveAspectFit
                            source: right.currentIndex == rightNymsTab ? "images/group_dark.png" : "images/group.png"
                        }

                        MouseArea {
                            anchors.fill: parent
                            onClicked: {
                                right.currentIndex = rightNymsTab
                            }
                        }
                    }
                }

                TabView {
                    id: right
                    Layout.fillHeight: true
                    Layout.fillWidth: true

                    focus: true
                    tabsVisible: false
                    frameVisible: false

                    currentIndex: rightThreadsTab

                    onCurrentIndexChanged: {
                        console.log("right tabview index changed:", currentIndex)

                        switch (currentIndex)
                        {
                            case rightThreadsTab:
                                if (0 <= sideThreadsTab.currentIndex)
                                {
                                    main.currentIndex = sideThreadsTab.currentIndex
                                }
                                break;
                        }
                    }

                    Tab {
                        id: sideThreadsTab
                        active: true
                        property int currentIndex: -1

                        SideThreadList {
                            anchors.fill: parent
                            width: 200 - 8

                            mainIndex: main.currentIndex
                            selectedPlace: selectedPlace

                            onCurrentIndexChanged:
                            {
                                sideThreadsTab.currentIndex = currentIndex
                                main.currentIndex = currentIndex
                            }

                            onSelectedThreadChanged:
                            {
                                console.log("selected thread changed:", selectedThread)
                                root.selectedThread = selectedThread
                                if (selectedThread)
                                {
                                    main.currentIndex = threadTab
                                }
                            }
                        }
                    }

                    Tab {
                        id: sideNymsTab

                        property int currentIndex: -1

                        SideNymList {
                            anchors.fill: parent
                            width: 200 - 8

                            mainIndex: main.currentIndex
                            selectedPlace: selectedPlace
                            selectedThread: selectedThread

                            onCurrentIndexChanged:
                            {
                                sideThreadsTab.currentIndex = currentIndex
                                main.currentIndex = currentIndex
                            }

                            onSelectedNymChanged:
                            {
                                console.log("selected nym changed:", selectedNym)
                                root.selectedThread = selectedThread
                                if (selectedThread)
                                {
                                    main.currentIndex = threadTab
                                }
                            }
                        }
                    }
                }

            }
        }
    }
}