exchange

Base system with REST service to issue digital coins, run by the payment service provider
Log | Files | Refs | Submodules | README | LICENSE

meson.build (1985B)

      1 configure_file(
      2     input: 'test_conversion.sh',
      3     output: 'test_conversion.sh',
      4     copy: true,
      5 )
      6 
      7 libtalerjson_src = [
      8     'conversion.c',
      9     'i18n.c',
     10     'json.c',
     11     'json_helper.c',
     12     'json_pack.c',
     13     'json_wire.c',
     14 ]
     15 
     16 libtalerjson = library(
     17     'talerjson',
     18     libtalerjson_src,
     19     soversion: solibversions['libtalerjson']['soversion'],
     20     version: solibversions['libtalerjson']['soversion'],
     21     install_rpath: rpath_option,
     22     dependencies: [
     23         libtalerutil_dep,
     24         gnunetutil_dep,
     25         gnunetjson_dep,
     26         json_dep,
     27         unistr_dep,
     28         m_dep,
     29     ],
     30     include_directories: [incdir, configuration_inc],
     31     install: true,
     32     install_dir: get_option('libdir'),
     33 )
     34 
     35 libtalerjson_dep = declare_dependency(link_with: libtalerjson)
     36 pkg.generate(
     37     libtalerjson,
     38     url: 'https://taler.net',
     39     description: 'GNU Taler JSON library',
     40 )
     41 
     42 talerjson_tests = ['test_conversion', 'test_json']
     43 
     44 talerjson_tests_installcheck = []
     45 
     46 foreach t : talerjson_tests
     47 
     48     test_tmp = executable(
     49         t,
     50         ['@0@.c'.format(t)],
     51         dependencies: [
     52             gnunetutil_dep,
     53             gnunetjson_dep,
     54             libtalerjson_dep,
     55             libtalerutil_dep,
     56             json_dep,
     57         ],
     58         include_directories: [incdir, configuration_inc],
     59         build_by_default: false,
     60         install: false,
     61     )
     62     test(
     63         t,
     64         test_tmp,
     65         workdir: meson.current_build_dir(),
     66         suite: ['json'],
     67         is_parallel: false,
     68     )
     69 endforeach
     70 
     71 foreach t : talerjson_tests_installcheck
     72 
     73     test_tmp = executable(
     74         t,
     75         ['@0@.c'.format(t)],
     76         dependencies: [gnunetutil_dep, libtalerutil_dep, json_dep],
     77         include_directories: [incdir, configuration_inc],
     78         build_by_default: false,
     79         install: false,
     80     )
     81     test(
     82         t,
     83         test_tmp,
     84         workdir: meson.current_build_dir(),
     85         suite: ['json', 'installcheck'],
     86         is_parallel: false,
     87     )
     88 
     89 
     90 endforeach