exchange

Base system with REST service to issue digital coins, run by the payment service provider
Log | Files | Refs | Submodules | README | LICENSE

meson.build (2827B)

      1 configure_file(
      2     input: 'test_typst.conf',
      3     output: 'test_typst.conf',
      4     configuration: cdata,
      5     install: false,
      6 )
      7 
      8 configure_file(
      9     input: 'test_typst_1.typ',
     10     output: 'test_typst_1.typ',
     11     configuration: cdata,
     12     install: false,
     13 )
     14 
     15 
     16 
     17 libtalermhd_src = [
     18     'mhd.c',
     19     'mhd_config.c',
     20     'mhd_legal.c',
     21     'mhd_parsing.c',
     22     'mhd_responses.c',
     23     'mhd_run.c',
     24     'mhd_spa.c',
     25     'mhd_typst.c',
     26 ]
     27 
     28 libtalermhd = library(
     29     'talermhd',
     30     libtalermhd_src,
     31     soversion: solibversions['libtalermhd']['soversion'],
     32     version: solibversions['libtalermhd']['soversion'],
     33     install_rpath: rpath_option,
     34     dependencies: [
     35         libtalerutil_dep,
     36         libtalerjson_dep,
     37         gnunetutil_dep,
     38         gnunetjson_dep,
     39         gnunetmhd_dep,
     40         json_dep,
     41         mhd_dep,
     42         zlib_dep,
     43     ],
     44     include_directories: [incdir, configuration_inc],
     45     install: true,
     46     install_dir: get_option('libdir'),
     47 )
     48 
     49 libtalermhd_dep = declare_dependency(link_with: libtalermhd)
     50 pkg.generate(
     51     libtalermhd,
     52     url: 'https://taler.net',
     53     description: 'GNU Taler microhttpd library',
     54 )
     55 
     56 talermhd_tests = ['test_typst', 'test_legal']
     57 
     58 foreach t : talermhd_tests
     59 
     60     test_tmp = executable(
     61         t,
     62         ['@0@.c'.format(t)],
     63         dependencies: [
     64             gnunetutil_dep,
     65             gnunetjson_dep,
     66             libtalermhd_dep,
     67             libtalerutil_dep,
     68             json_dep,
     69             mhd_dep,
     70             curl_dep,
     71         ],
     72         include_directories: [incdir, configuration_inc],
     73         build_by_default: false,
     74         install: false,
     75     )
     76     test(
     77         t,
     78         test_tmp,
     79         workdir: meson.current_build_dir(),
     80         env: ['PWD=' + meson.current_build_dir()],
     81         suite: ['mhd'],
     82         is_parallel: false,
     83     )
     84 endforeach
     85 
     86 if mhd2_dep.found()
     87 
     88     libtalermhd2_src = [
     89         'mhd2.c',
     90         'mhd_config.c',
     91         'mhd2_legal.c',
     92         'mhd2_responses.c',
     93         'mhd2_run.c',
     94         'mhd2_spa.c',
     95     ]
     96 
     97     libtalermhd2 = library(
     98         'talermhd2',
     99         libtalermhd2_src,
    100         soversion: solibversions['libtalermhd2']['soversion'],
    101         version: solibversions['libtalermhd2']['soversion'],
    102         install_rpath: rpath_option,
    103         dependencies: [
    104             libtalerutil_dep,
    105             libtalerjson_dep,
    106             gnunetutil_dep,
    107             gnunetjson_dep,
    108             gnunetmhd_dep,
    109             json_dep,
    110             mhd2_dep,
    111             zlib_dep,
    112         ],
    113         include_directories: [incdir, configuration_inc],
    114         install: true,
    115         install_dir: get_option('libdir'),
    116     )
    117 
    118     libtalermhd2_dep = declare_dependency(link_with: libtalermhd2)
    119     pkg.generate(
    120         libtalermhd2,
    121         url: 'https://taler.net',
    122         description: 'GNU Taler microhttpd2 wrapper library',
    123     )
    124 
    125 endif